Macaulay2 » Documentation
Packages » MatrixFactorizations :: ZZdfactorization(HashTable)
next | previous | forward | backward | up | index | toc

ZZdfactorization(HashTable) -- make a ZZ/d-graded factorization

Description

A ZZ/d-graded factorization is a sequence of objects $C_i$, connected by maps $dd^C_i : C_i \rightarrow C_{i-1}$ such that the composition of any d consecutive maps is equal to a fixed scalar multiple of the identity.

In practice, a ZZdFactorization may be visualized as a sequence of R-module maps:

$$F_0 \leftarrow F_1 \leftarrow \cdots \leftarrow F_{d-1}$$

with the caveat that $d^F_0 : F_0 \to F_{d-1}$, since one should count degree modulo d.

i1 : S = ZZ/101[a..d]

o1 = S

o1 : PolynomialRing
 
i2 : F1 = map(S^2,S^2,matrix {{d, b}, {a, c}})

o2 = | d b |
     | a c |

             2      2
o2 : Matrix S  <-- S
 
i3 : F2 = map(source F1,S^2,matrix {{-c, b}, {a, -d}})

o3 = | -c b  |
     | a  -d |

             2      2
o3 : Matrix S  <-- S
 
i4 : C = ZZdfactorization hashTable{1 => F1, 2 => F2}

      2      2      2
o4 = S  <-- S  <-- S
                    
     0      1      0

o4 : ZZdFactorization
 
i5 : C.dd

          2                 2
o5 = 1 : S  <------------- S  : 0
               | -c b  |
               | a  -d |

          2               2
     0 : S  <----------- S  : 1
               | d b |
               | a c |

o5 : ZZdFactorizationMap
 
i6 : isWellDefined C

o6 = true
 
i7 : isdFactorization C

o7 = (true, a*b - c*d)

o7 : Sequence
 
i8 : C.dd^2

          2                       2
o8 = 0 : S  <------------------- S  : 0
               | ab-cd 0     |
               | 0     ab-cd |

          2                       2
     1 : S  <------------------- S  : 1
               | ab-cd 0     |
               | 0     ab-cd |

o8 : ZZdFactorizationMap

This is the primary constructor used by all of the more user friendly methods for constructing a ZZ/d-graded factorization.

Caveat

This constructor minimizes computation and does very little error checking. To verify that a complex is well constructed, use isWellDefined(ZZdFactorization).

See also

Ways to use this method:

The source of this document is in MatrixFactorizations/MatrixFactorizationsDOC.m2:540:0.