Macaulay2 » Documentation
Packages » MatrixFactorizations :: cone(ZZdFactorizationMap)
next | previous | forward | backward | up | index | toc

cone(ZZdFactorizationMap) -- make the mapping cone of a morphism of ZZ/d-graded factorizations

Description

Given a morphism $f \colon B \to C$, the mapping cone is the factorization whose $i$-th term is $B_{i-1} \oplus C_i$, and whose $i$-th differential is given by \[ \begin{bmatrix} -\operatorname{dd}^{B[-1]} & 0 \\ f[-1] & \operatorname{dd}^C \end{bmatrix}. \]

A map between modules induces a map between their free resolutions, and we compute the associated mapping cone.

i1 : S = ZZ/101[a,b];
 
i2 : R = S/(a^3+b^3);
 
i3 : m = ideal vars R

o3 = ideal (a, b)

o3 : Ideal of R
 
i4 : use S;
 
i5 : C = tailMF m

      2      2      2
o5 = S  <-- S  <-- S
                    
     0      1      0

o5 : ZZdFactorization
 
i6 : D = tailMF (m^2)

      3      3      3
o6 = S  <-- S  <-- S
                    
     0      1      0

o6 : ZZdFactorization
 
i7 : f = randomFactorizationMap(D, C, Cycle => true, InternalDegree => 2)

          3                                      2
o7 = 0 : S  <---------------------------------- S  : 0
               {3} | 20a+29b 24a2-17ab+9b2  |
               {3} | 10a-19b 30a2-48ab-7b2  |
               {3} | 32a-36b 19a2-11ab-21b2 |

          3                                2
     1 : S  <---------------------------- S  : 1
               {5} | 20a+21b 24a-36b  |
               {5} | -10a+9b -30a-29b |
               {5} | 32a-7b  19a+19b  |

o7 : ZZdFactorizationMap
 
i8 : Cf = cone f

      5      5      5
o8 = S  <-- S  <-- S
                    
     0      1      0

o8 : ZZdFactorization
 
i9 : dd^Cf

          5                                                  5
o9 = 1 : S  <---------------------------------------------- S  : 0
               {4} | a       b2             0   0   0   |
               {4} | -b      a2             0   0   0   |
               {3} | 20a+29b 24a2-17ab+9b2  -a2 -b2 -ab |
               {3} | 10a-19b 30a2-48ab-7b2  -ab a2  -b2 |
               {3} | 32a-36b 19a2-11ab-21b2 b2  -ab -a2 |

          5                                         5
     0 : S  <------------------------------------- S  : 1
               {2} | a2      -b2      0  0  0  |
               {3} | b       a        0  0  0  |
               {5} | 20a+21b 24a-36b  -a 0  b  |
               {5} | -10a+9b -30a-29b -b a  0  |
               {5} | 32a-7b  19a+19b  0  -b -a |

o9 : ZZdFactorizationMap
 
i10 : isdFactorization Cf

              3    3
o10 = (true, a  + b )

o10 : Sequence
 
i11 : cone inducedMap(coker f, target f)

o11 = cokernel {3} | 0       0        | <-- cokernel {5} | 0       0              | <-- cokernel {3} | 0       0        |
               {3} | 0       0        |              {5} | 0       0              |              {3} | 0       0        |
               {3} | 0       0        |              {5} | 0       0              |              {3} | 0       0        |
               {5} | 20a+21b 24a-36b  |              {3} | 20a+29b 24a2-17ab+9b2  |              {5} | 20a+21b 24a-36b  |
               {5} | -10a+9b -30a-29b |              {3} | 10a-19b 30a2-48ab-7b2  |              {5} | -10a+9b -30a-29b |
               {5} | 32a-7b  19a+19b  |              {3} | 32a-36b 19a2-11ab-21b2 |              {5} | 32a-7b  19a+19b  |
                                                                                         
      0                                     1                                           0

o11 : ZZdFactorization
 
i12 : isdFactorization oo

              3    3
o12 = (true, a  + b )

o12 : Sequence

The mapping cone fits into a canonical short exact sequence of factorizations: $$0 \to C \to \operatorname{cone}(f) \to B[1] \to 0.$$

See also

Ways to use this method:

The source of this document is in MatrixFactorizations/MatrixFactorizationsDOC.m2:4487:0.