Macaulay2 » Documentation
Packages » MatrixFactorizations :: dual(ZZdFactorizationMap)
next | previous | forward | backward | up | index | toc

dual(ZZdFactorizationMap) -- the dual of a map of ZZ/d-graded factorizations

Description

The map $f : C \to D$ of ZZ/d-graded factorizations over the ring $S$ induces the map $h = Hom(f, S^1) : Hom(D, S^1) \to Hom(C,S^1)$ defined by $\phi \mapsto \phi f$.

i1 : S = ZZ/101[a,b];
 
i2 : R = S/(a^3+b^3);
 
i3 : m = ideal vars R

o3 = ideal (a, b)

o3 : Ideal of R
 
i4 : C = tailMF m

      2      2      2
o4 = S  <-- S  <-- S
                    
     0      1      0

o4 : ZZdFactorization
 
i5 : D = tailMF (m^2)

      3      3      3
o5 = S  <-- S  <-- S
                    
     0      1      0

o5 : ZZdFactorization
 
i6 : f = randomFactorizationMap(C,D)

          2                                         3
o6 = 0 : S  <------------------------------------- S  : 0
               {2} | 24a-36b -29a+19b -10a-29b |
               {3} | -30     19       -8       |

          2                                          3
     1 : S  <-------------------------------------- S  : 1
               {4} | -22a-29b -16a+39b 19a-47b  |
               {4} | -24a-38b 21a+34b  -39a-18b |

o6 : ZZdFactorizationMap
 
i7 : h = dual f

          3                                  2
o7 = 0 : S  <------------------------------ S  : 0
               {-3} | -22a-29b -24a-38b |
               {-3} | -16a+39b 21a+34b  |
               {-3} | 19a-47b  -39a-18b |

          3                             2
     1 : S  <------------------------- S  : 1
               {-5} | 24a-36b  -30 |
               {-5} | -29a+19b 19  |
               {-5} | -10a-29b -8  |

o7 : ZZdFactorizationMap
 
i8 : assert isWellDefined h

This routine is functorial.

i9 : D' = tailMF (trim m^3)

      3      3      3
o9 = S  <-- S  <-- S
                    
     0      1      0

o9 : ZZdFactorization
 
i10 : f' = randomFactorizationMap(D, D')

           3                                          3
o10 = 0 : S  <-------------------------------------- S  : 0
                {3} | -13a-43b 2a+16b   -47a+47b |
                {3} | -15a-28b 22a+45b  19a-16b  |
                {3} | -47a+38b -34a-48b 7a+15b   |

           3                                        3
      1 : S  <------------------------------------ S  : 1
                {5} | -23a+39b 36a+35b 11a+46b |
                {5} | 43a-17b  11a-38b -28a+b  |
                {5} | -11a+48b 33a+40b -3a+22b |

o10 : ZZdFactorizationMap
 
i11 : dual(f * f') == dual f' * dual f

o11 = true

See also

Ways to use this method:

The source of this document is in MatrixFactorizations/MatrixFactorizationsDOC.m2:3664:0.