An element of the factorization $\operatorname{Hom}(C, D)$ corresponds to a map of factorizations from $C$ to $D$. Given an element in the $i$-th term, this method returns the corresponding map of complexes of degree $i$.
As a first example, consider two Koszul complexes $C$ and $D$. From a random map $f \colon R^1 \to Hom(C, D)$, we construct the corresponding map of chain complexes $g \colon C \to D$.
i1 : S = ZZ/101[a,b];
|
i2 : R = S/(a^3+b^3);
|
i3 : m = ideal vars R
o3 = ideal (a, b)
o3 : Ideal of R
|
i4 : C = tailMF m
2 2 2
o4 = S <-- S <-- S
0 1 0
o4 : ZZdFactorization
|
i5 : D = tailMF (m^2)
3 3 3
o5 = S <-- S <-- S
0 1 0
o5 : ZZdFactorization
|
i6 : E = Hom(C,D)
12 12 12
o6 = S <-- S <-- S
0 1 0
o6 : ZZdFactorization
|
i7 : f = random(E_2, S^{-5})
o7 = {1} | 24a4-22a3b-47a2b2+2ab3-16b4 |
{1} | -36a4-29a3b-39a2b2+16ab3+7b4 |
{1} | -30a4-24a3b-18a2b2+22ab3+15b4 |
{0} | 36a5-38a4b+11a3b2+a2b3-47ab4+2b5 |
{0} | 35a5+33a4b+46a3b2-3a2b3-23ab4+29b5 |
{0} | 11a5+40a4b-28a3b2+22a2b3-7ab4-47b5 |
{1} | -29a4-38a3b-13a2b2+45ab3-23b4 |
{1} | 19a4-16a3b-43a2b2-34ab3+39b4 |
{1} | 19a4+39a3b-15a2b2-48ab3+43b4 |
{1} | -10a4+21a3b-28a2b2-47ab3-17b4 |
{1} | -29a4+34a3b-47a2b2+47ab3-11b4 |
{1} | -8a4+19a3b+38a2b2+19ab3+48b4 |
12 1
o7 : Matrix S <-- S
|
i8 : g = homomorphism(2, f, E)
3 2
o8 = 0 : S <---------------------------------------------------------------------------- S : 0
{3} | 24a4-22a3b-47a2b2+2ab3-16b4 36a5-38a4b+11a3b2+a2b3-47ab4+2b5 |
{3} | -36a4-29a3b-39a2b2+16ab3+7b4 35a5+33a4b+46a3b2-3a2b3-23ab4+29b5 |
{3} | -30a4-24a3b-18a2b2+22ab3+15b4 11a5+40a4b-28a3b2+22a2b3-7ab4-47b5 |
3 2
1 : S <----------------------------------------------------------------------- S : 1
{5} | -29a4-38a3b-13a2b2+45ab3-23b4 -10a4+21a3b-28a2b2-47ab3-17b4 |
{5} | 19a4-16a3b-43a2b2-34ab3+39b4 -29a4+34a3b-47a2b2+47ab3-11b4 |
{5} | 19a4+39a3b-15a2b2-48ab3+43b4 -8a4+19a3b+38a2b2+19ab3+48b4 |
o8 : ZZdFactorizationMap
|
i9 : assert isWellDefined g
|
i10 : assert not isCommutative g
|
The map $g \colon C \to D$ corresponding to a random map into $Hom(C,D)$ does not generally commute with the differentials. However, if the element of $Hom(C,D)$ is a cycle, then the corresponding map does commute.
i11 : h = randomFactorizationMap(E, ZZdfactorization(S^{-2}, 2), Cycle => true)
12 1
o11 = 0 : S <-------------------------- S : 0
{1} | -26a+10b |
{1} | -3a+18b |
{1} | -7a-37b |
{0} | 15a2-7ab+44b2 |
{0} | 13a2+25ab-10b2 |
{0} | 30a2-31ab-32b2 |
{1} | -26a+32b |
{1} | 3a+44b |
{1} | -7a-10b |
{1} | 15a-37b |
{1} | -13a-10b |
{1} | 30a-18b |
12
1 : S <----- 0 : 1
0
o11 : ZZdFactorizationMap
|
i12 : f = h_0
o12 = {1} | -26a+10b |
{1} | -3a+18b |
{1} | -7a-37b |
{0} | 15a2-7ab+44b2 |
{0} | 13a2+25ab-10b2 |
{0} | 30a2-31ab-32b2 |
{1} | -26a+32b |
{1} | 3a+44b |
{1} | -7a-10b |
{1} | 15a-37b |
{1} | -13a-10b |
{1} | 30a-18b |
12 1
o12 : Matrix S <-- S
|
i13 : g = homomorphism(0, f, E)
3 2
o13 = 0 : S <----------------------------------- S : 0
{3} | -26a+10b 15a2-7ab+44b2 |
{3} | -3a+18b 13a2+25ab-10b2 |
{3} | -7a-37b 30a2-31ab-32b2 |
3 2
1 : S <----------------------------- S : 1
{5} | -26a+32b 15a-37b |
{5} | 3a+44b -13a-10b |
{5} | -7a-10b 30a-18b |
o13 : ZZdFactorizationMap
|
i14 : assert isWellDefined g
|
i15 : assert isCommutative g
|
i16 : assert(degree g === 0)
|
i17 : assert(source g === C)
|
i18 : assert(target g === D)
|
i19 : assert(homomorphism' g == h)
|