Macaulay2 » Documentation
Packages » MatrixFactorizations :: randomFactorizationMap
next | previous | forward | backward | up | index | toc

randomFactorizationMap -- a random map of ZZ/d-graded factorizations

Description

A random ZZ/d-graded factorization map $f : C \to D$ is obtained from a random element in the ZZ/d-graded factorization $Hom(C,D)$.

i1 : S = ZZ/101[a,b];
 
i2 : R = S/(a^3+b^3);
 
i3 : m = ideal vars R

o3 = ideal (a, b)

o3 : Ideal of R
 
i4 : C = tailMF m

      2      2      2
o4 = S  <-- S  <-- S
                    
     0      1      0

o4 : ZZdFactorization
 
i5 : D = tailMF (m^2)

      3      3      3
o5 = S  <-- S  <-- S
                    
     0      1      0

o5 : ZZdFactorization
 
i6 : f = randomFactorizationMap(D,C)

          3                     2
o6 = 0 : S  <----------------- S  : 0
               {3} | 0 24  |
               {3} | 0 -36 |
               {3} | 0 -30 |

          3         2
     1 : S  <----- S  : 1
               0

o6 : ZZdFactorizationMap
 
i7 : assert isWellDefined f
 
i8 : assert not isCommutative f

When the random element in the factorization $Hom(C,D)$ lies in the kernel of the differential, the associated map of complexes commutes with the differential.

i9 : g = randomFactorizationMap(D,C, Cycle => true, InternalDegree => 2)

          3                                        2
o9 = 0 : S  <------------------------------------ S  : 0
               {3} | -41a+10b -29a2-10ab-30b2 |
               {3} | -43a+8b  -19a2-19ab+48b2 |
               {3} | -5a+19b  -29a2+11ab+14b2 |

          3                                 2
     1 : S  <----------------------------- S  : 1
               {5} | -41a-14b -29a+19b |
               {5} | 43a-30b  19a-10b  |
               {5} | -5a+48b  -29a-8b  |

o9 : ZZdFactorizationMap
 
i10 : assert isWellDefined g
 
i11 : assert isCommutative g
 
i12 : assert isFactorizationMorphism g

Assume that $C$ and $D$ are factorizations of the same potential. Then the factorization $Hom(C,D)$ is actually a ZZ/d-graded complex. When the random element in the factorization $Hom(C,D)$ lies in the image of the differential, the associated map of complexes is a null homotopy.

i13 : h = randomFactorizationMap(D,C, Boundary => true)

           3                                     2
o13 = 0 : S  <--------------------------------- S  : 0
                {3} | -38ab-21b2 21a2b-38b3 |
                {3} | -16ab-34b2 34a2b-16b3 |
                {3} | 39ab-19b2  19a2b+39b3 |

           3                                     2
      1 : S  <--------------------------------- S  : 1
                {5} | -38ab-39b2 21ab-19b2  |
                {5} | 16ab-38b2  -34ab+21b2 |
                {5} | 39ab-16b2  19ab+34b2  |

o13 : ZZdFactorizationMap
 
i14 : assert isWellDefined h
 
i15 : assert isCommutative h
 
i16 : assert isFactorizationMorphism h

When the degree of the random element in the factorization $Hom(C,D)$ is non-zero, the associated map of factorizations has the same degree.

i17 : p = randomFactorizationMap(D, C, Cycle => true, Degree => 1)

           3         2
o17 = 1 : S  <----- S  : 0
                0

           3         2
      0 : S  <----- S  : 1
                0

o17 : ZZdFactorizationMap
 
i18 : assert isWellDefined p
 
i19 : assert isCommutative p
 
i20 : assert not isFactorizationMorphism p
 
i21 : assert(degree p === 1)

By default, the random element is constructed as a random linear combination of the basis elements in the appropriate degree of $Hom(C,D)$. Given an internal degree, the random element is constructed as maps of modules with this degree.

i22 : q = randomFactorizationMap(D, C, Boundary => true, InternalDegree => 2)

           3                                                       2
o22 = 0 : S  <--------------------------------------------------- S  : 0
                {3} | -13ab3+28b4 -28a2b3-13b5-47a2-18ab-39b2 |
                {3} | -43ab3+47b4 -47a2b3-43b5+39a2-47ab-18b2 |
                {3} | -15ab3-38b4 38a2b3-15b5-18a2-39ab+47b2  |

           3                                               2
      1 : S  <------------------------------------------- S  : 1
                {5} | -13ab3+15b4-47b -28ab3-38b4-47a |
                {5} | 43ab3-13b4-39b  47ab3-28b4-39a  |
                {5} | -15ab3-43b4-18b 38ab3-47b4-18a  |

o22 : ZZdFactorizationMap
 
i23 : assert all({0,1,2}, i -> degree q_i === {2})
 
i24 : assert isWellDefined q
 
i25 : assert isCommutative q
 
i26 : assert isFactorizationMorphism q
 
i27 : source q === C

o27 = true
 
i28 : target q === D

o28 = true

See also

Ways to use randomFactorizationMap:

  • randomFactorizationMap(ZZdFactorization,ZZdFactorization)

For the programmer

The object randomFactorizationMap is a method function with options.

The source of this document is in MatrixFactorizations/MatrixFactorizationsDOC.m2:4649:0.