adjointWord -- image of a word through the shuffle algebra homomorphism induced by a polynomial map

Usage:

adjointWord (g, T, L)
Inputs:
- g, an instance of the type NCRingElement, the word to compute the image of;
- T, an instance of the type NCPolynomialRing, the shuffle algebra of the image;
- L, a list, the components of the polynomial map. each entry should be a polynomial;

Description

This computes the image of g through the map $M_p$ described in Theorem 1 and Theorem 7 of [1]. Its importance is evidenced by Theorem 2 of the same paper:

Let $X:[0,1]\rightarrow \mathbb{R}^d$ be a piecewise continuously differentiable path with $X(0) = 0$ and let $p : \mathbb{R}^n \rightarrow \mathbb{R}^m$ be a polynomial map with $p(0) = 0$. Then, for all $w ∈ T(\mathbb{R}^m)$ one has $$ \sigma(p(X)) = M_p^*(\sigma(X))$$ (where $\sigma(X)$ is the signature of $X$ and $M_p^*$ is the dual map of $M_p$).

As a use example, we verify this in a particular case. First we define a transformation of affine spaces and create the word algebra where our tensors live

i1 : S = QQ[x,y];

i2 : p = {x^2,x*y,y^2} -- A map of affine spaces, the degree 2 Veronese morphism R^2 -> R^3

       2        2
o2 = {x , x*y, y }

o2 : List

i3 : wA2 = wordAlgebra(2); -- signatures of paths in dimension 2

i4 : wA3 = wordAlgebra(3); -- signatures of paths in dimension 3

Then we define a path in the domain space and explicitly compute its image under the polynomial map above:

i5 : R = QQ[t];

i6 : X = polyPath({t,t^2}) -- A path in 2 dimensional space

o6 = Path in 2-dimensional space with 1 polynomial segment:

           2
     {{t, t }}

o6 : Path

i7 : PP = apply(p, q -> sub(q, {x=>t, y=>t^2}));

i8 : Y = polyPath(PP) -- the transformed path in 3 dimensional space

o8 = Path in 3-dimensional space with 1 polynomial segment:

        2   3   4
     {{t , t , t }}

o8 : Path

Finally we compute the signature of the transformed path along the sgnVolTensor tensor of $\mathbb{R}^3$ and verify the formula in Theorem 2 above:

i9 : vol = sgnVolTensor(wA3); vol // wordFormat -- consider the signed volume in R^3 and display it in word format

        1             1             1             1             1            
o10 = - - [3, 2, 1] + - [3, 1, 2] + - [2, 3, 1] - - [2, 1, 3] - - [1, 3, 2] +
        6             6             6             6             6            
      -----------------------------------------------------------------------
      1
      - [1, 2, 3]
      6

i11 : adw = adjointWord(vol, wA2, p); adw // wordFormat -- we compute its image through the induced homomorphism on algebras

                               2                      2                     
o12 = - 2 [2, 2, 2, 1, 1, 1] + - [2, 2, 1, 2, 1, 1] + - [2, 2, 1, 1, 2, 1] +
                               3                      3                     
      -----------------------------------------------------------------------
      2                      2                      2                      2
      - [2, 2, 1, 1, 1, 2] + - [2, 1, 2, 2, 1, 1] + - [2, 1, 2, 1, 2, 1] + -
      3                      3                      3                      3
      -----------------------------------------------------------------------
                           2                      2                      2
      [2, 1, 2, 1, 1, 2] - - [2, 1, 1, 2, 2, 1] - - [2, 1, 1, 2, 1, 2] - -
                           3                      3                      3
      -----------------------------------------------------------------------
                           2                      2                      2
      [2, 1, 1, 1, 2, 2] + - [1, 2, 2, 2, 1, 1] + - [1, 2, 2, 1, 2, 1] + -
                           3                      3                      3
      -----------------------------------------------------------------------
                           2                      2                      2
      [1, 2, 2, 1, 1, 2] - - [1, 2, 1, 2, 2, 1] - - [1, 2, 1, 2, 1, 2] - -
                           3                      3                      3
      -----------------------------------------------------------------------
                           2                      2                      2
      [1, 2, 1, 1, 2, 2] - - [1, 1, 2, 2, 2, 1] - - [1, 1, 2, 2, 1, 2] - -
                           3                      3                      3
      -----------------------------------------------------------------------
      [1, 1, 2, 1, 2, 2] + 2 [1, 1, 1, 2, 2, 2]

i13 : sig(Y, vol)  -- the signed volume of the transformed path

       1
o13 = ---
      630

o13 : QQ

i14 : sig(X, adw)  -- is given by evaluating at adw for the original path.

       1
o14 = ---
      630

o14 : QQ

References

[1] Signatures of paths transformed by polynomial maps (doi.org/10.1007/s13366-020-00493-9)

Ways to use adjointWord:

adjointWord(NCRingElement,NCPolynomialRing,List)

For the programmer

The object adjointWord is a method function.

The source of this document is in PathSignatures/documentation.m2:918:0.