bettiMAC -- compute the Betti numbers of a moment-angle complex

Usage:

bettiMAC(k,Z)

bettiMAC(Z)
Inputs:
- k, an integer, (optional)
- Z, a moment-angle complex,
Outputs:
- an integer, the k-th Betti number of the moment angle complex (if k is provided)
- a list, of all Betti numbers

Description

This method computes the Betti numbers of a moment-angle complex using the theorem of Baskakov-Buchstaber-Panov. If a dimension k is specified, then only the k-th Betti number of Z is computed. If no dimension is specified, all the Betti numbers between 0 and 2m are computed (where m is the number of vertices in the underlying simplicial complex).

The moment-angle complex corresponding to the simplicial complex consisting of two disjoint vertices is homeomorphic to $S^3$, the 3-sphere as indicated by its Betti numbers.

i1 : needsPackage "SimplicialComplexes"

o1 = SimplicialComplexes

o1 : Package

i2 : R = QQ[x,y]

o2 = R

o2 : PolynomialRing

i3 : K = simplicialComplex {x, y}

o3 = simplicialComplex | y x |

o3 : SimplicialComplex

i4 : Z = momentAngleComplex K

o4 = MomentAngleComplex{MACSimplicialComplex => simplicialComplex | y x |}

o4 : MomentAngleComplex

i5 : bettiMAC Z

o5 = {1, 0, 0, 1, 0}

o5 : List

Let $\mathcal{Z}_K$ be the moment-angle corresponding to the simplicial complex consisting on 3 vertices, with an edge and a disjoint vertex. By Hochster's formula, its third cohomology $H^3(\mathcal{Z}_K)$ will have rank $2$. We can verify this as follows,

i6 : needsPackage "SimplicialComplexes"

o6 = SimplicialComplexes

o6 : Package

i7 : R = QQ[x..z]

o7 = R

o7 : PolynomialRing

i8 : K = simplicialComplex {x, y*z}

o8 = simplicialComplex | x yz |

o8 : SimplicialComplex

i9 : Z = momentAngleComplex K

o9 = MomentAngleComplex{MACSimplicialComplex => simplicialComplex | x yz |}

o9 : MomentAngleComplex

i10 : bettiMAC (3, Z)

o10 = 2

The moment-angle corresponding to the boundary $\partial \Delta^2$ of the 2-simplex is homeomorphic to $S^5$, as reflected by its Betti numbers.

i11 : needsPackage "SimplicialComplexes"

o11 = SimplicialComplexes

o11 : Package

i12 : R = QQ[x..z]

o12 = R

o12 : PolynomialRing

i13 : K = simplicialComplex {x*y, y*z, x*z}

o13 = simplicialComplex | yz xz xy |

o13 : SimplicialComplex

i14 : Z = momentAngleComplex K

o14 = MomentAngleComplex{MACSimplicialComplex => simplicialComplex | yz xz xy |}

o14 : MomentAngleComplex

i15 : bettiMAC Z

o15 = {1, 0, 0, 0, 0, 1, 0}

o15 : List

Ways to use bettiMAC:

bettiMAC(MomentAngleComplex)
bettiMAC(ZZ,MomentAngleComplex)

For the programmer

The object bettiMAC is a method function.

The source of this document is in ToricTopology.m2:783:0.