inhomogeneousSystemOfParameters -- generates an inhomogeneous system of parameters

Usage:

inhomogeneousSystemOfParameters(I,A)
Inputs:
- I, an ideal
- A, a ring
Optional inputs:
- Attempts => an integer, default value 100, number of attempts made to generate an inhomogeneous system of parameters
- Bound => an integer, default value 1, bound on the value of the random coefficients
- Sparseness => a real number, default value .5, between 0 and 1 giving the frequency of the coefficients being equal to zero
- Maximal => a Boolean value, default value true, whether to insist on searching for a maximal inhomogeneous system of parameters
Outputs:
- a matrix

Description

Given a ring and an ideal, inhomogeneousSystemOfParameters attempts to generate an inhomogeneous system of parameters contained in I. The algorithm is based on one found in Chapter 5.5 of W. Vasconcelos' book: Computational Methods in Commutative Algebra and Algebraic Geometry.

i1 : A = ZZ/5051[x, y, z];

i2 : I = ideal (x, x*y, y*z);

o2 : Ideal of A

i3 : X = inhomogeneousSystemOfParameters(I,A)

o3 = | yz+x xy |

             1      2
o3 : Matrix A  <-- A

i4 : isRegularSequence(X,A)

o4 = true

Here are examples with optional inputs:

i5 : A = ZZ/5051[x, y, z];

i6 : I = ideal (x, x*y, y*z);

o6 : Ideal of A

i7 : inhomogeneousSystemOfParameters(I,A,Attempts=>1,Bound=>100,Sparseness=>.9)
--warning: no maximal regular sequence found

o7 = 0

             1
o7 : Matrix A  <-- 0

Here are examples with the optional input Maximal => false:

i8 : x = symbol x; y = symbol y;

i10 : n = 2;

i11 : A = ZZ/101[x_(1,1)..x_(n,n),y_(1,1)..y_(n,n)];

i12 : X = transpose genericMatrix(A,n,n);

              2      2
o12 : Matrix A  <-- A

i13 : Y = transpose genericMatrix(A,y_(1,1),n,n);

              2      2
o13 : Matrix A  <-- A

i14 : b = ideal(X*Y - Y*X);

o14 : Ideal of A

i15 : B = A/b;

i16 : inhomogeneousSystemOfParameters(B,Attempts=>1,Maximal=>false)

o16 = | -x_(2,1)-y_(1,2)+y_(2,1) x_(1,2)-y_(2,2)
      -----------------------------------------------------------------------
      -x_(2,1)+x_(2,2)-y_(1,1)+y_(1,2) -x_(1,1)+x_(2,1)
      -----------------------------------------------------------------------
      x_(1,1)-x_(2,1)-y_(1,1) x_(1,1)+x_(1,2) |

              1      6
o16 : Matrix B  <-- B

This symbol is provided by the package Depth.

Ways to use inhomogeneousSystemOfParameters:

inhomogeneousSystemOfParameters(Ideal)
inhomogeneousSystemOfParameters(Ideal,Ring)
inhomogeneousSystemOfParameters(Ring)

For the programmer

The object inhomogeneousSystemOfParameters is a method function with options.

The source of this document is in /__w/M2/M2/macaulay2-1.26.05+ds/M2/Macaulay2/packages/Depth.m2:807:0.