pfaffianSystem -- computes the Pfaffian system of a $D_n$-ideal $I$ for a chosen basis

Usage:

pfaffianSystem I

pfaffianSystem(I, B)
Inputs:
- I, an ideal, $D_n$-ideal
- B, a list, a basis of $R_n/R_nI$
Outputs:
- A, a list, Pfaffian system of $I$ over the base fraction field of $D_n$

Description

Let $I$ be an ideal in the Weyl algebra $D_n$ and $B$ a basis for $R_n/R_nI$ over the base fraction field of $D_n$. If no basis is provided by the user, the basis is chosen to be the set of standard monomials of a Gröbner basis on $R_nI$ with regards to the weighted Lex order $(\partial_1 > \cdots > \partial_n > x_1 > \cdots > x_n)$ on the Weyl algebra. The following example computes the Pfaffian system for the $D$-ideal annihilating $1/x$ and $1/y$.

i1 : D = makeWeylAlgebra(QQ[x,y], {2, 1})

o1 = D

o1 : PolynomialRing, 2 differential variable(s)

i2 : I = ideal (x*dx^2-y*dy^2+2*dx-2*dy, x*dx+y*dy+1)

                2             2
o2 = ideal (x*dx  + 2dx - y*dy  - 2dy, x*dx + y*dy + 1)

o2 : Ideal of D

i3 : A = pfaffianSystem I

o3 = {| -1/x -y/x |, | 0 1    |}
      | 0    0    |  | 0 -2/y |

o3 : List

The following example computes the Pfaffian system for the $D$-ideal annihilating $sin(xy)$ and $cos(xy)$, with respect to the basis $\{1,dx\}$.

i4 : D = makeWeylAlgebra(QQ[x,y]);

i5 : I = ideal (dx^2-y^2, dy^2-x^2);

o5 : Ideal of D

i6 : A = pfaffianSystem(I,{1_D,dx})

o6 = {| 0  1 |, | 0  x/y |}
      | y2 0 |  | xy 1/y |

o6 : List

The command pfaffianSystem(I,B) computes the Pfaffian system of $I$ with respect to the basis of standard monomials of $I$ and then performs a gauge transformation to the provided basis $B$.

i7 : B = pfaffianSystem(I)

o7 = {| 0  y/x |, | 0  1 |}
      | xy 1/x |  | x2 0 |

o7 : List

i8 : M = gaugeMatrix(I,{1_D,dx})

o8 = | 1 0   |
     | 0 y/x |

                            2                     2
o8 : Matrix (frac(QQ[x..y]))  <-- (frac(QQ[x..y]))

i9 : A2 = gaugeTransform(M,B)

o9 = {| 0  1 |, | 0  x/y |}
      | y2 0 |  | xy 1/y |

o9 : List

References

For more details, see [SST, pp. 37-40].

Ways to use pfaffianSystem:

pfaffianSystem(Ideal)
pfaffianSystem(Ideal,List)

For the programmer

The object pfaffianSystem is a method function.

The source of this document is in ConnectionMatrices/docs.m2:226:0.