idealOrlikSolomonAlgebra -- the defining ideal of the Orlik-Solomon algebra

Usage:

idealOrlikSolomonAlgebra M
Inputs:
- M, a matroid,
Optional inputs:
- CoefficientRing => ..., default value QQ
- Variable => ..., default value "e"
Outputs:
- an ideal, the defining ideal of the Orlik-Solomon algebra of M

Description

The Orlik-Solomon algebra of a matroid M of rank r is the skew-commutative quotient $A(M) = E/J(M)$, where $E$ is the exterior algebra on generators $e_x$ for $x \in M$, and $J(M)$ is the ideal generated, for each circuit $C = \{x_0, \ldots, x_k\}$ of M, by $\sum_{i=0}^k (-1)^i e_{x_0} \cdots \widehat{e_{x_i}} \cdots e_{x_k}$. This method returns the ideal $J(M)$.

By the Orlik-Solomon theorem, the Hilbert series of $A(M)$ is $\sum_{i=0}^r |w_i(M)| T^i$, where $w_i(M)$ are the (unsigned) Whitney numbers of the first kind of M — i.e., the absolute values of the coefficients of the characteristic polynomial.

i1 : M = matroid completeGraph 3

o1 = a "matroid" of rank 2 on 3 elements

o1 : Matroid

i2 : I = idealOrlikSolomonAlgebra M

o2 = ideal(e e  - e e  + e e )
            0 1    0 2    1 2

o2 : Ideal of QQ[e ..e ]
                  0   2

i3 : A = (ring I)/I;

i4 : numerator hilbertSeries(A, Order => rank M + 1)

                2
o4 = 1 + 3T + 2T

o4 : ZZ[T]

i5 : characteristicPolynomial M

      2
o5 = x  - 3x + 2

o5 : ZZ[x]

The coefficient ring of the ambient exterior algebra can be set with the CoefficientRing option, and the variable name with the Variable option.

i6 : I = idealOrlikSolomonAlgebra(matroid completeGraph 4, CoefficientRing => ZZ/5, Variable => "f")

o6 = ideal (f f  - f f  + f f , f f  - f f  + f f , f f  - f f  + f f , f f 
             3 4    3 5    4 5   1 2    1 5    2 5   0 2    0 4    2 4   0 1
     ------------------------------------------------------------------------
     - f f  + f f )
        0 3    1 3

              ZZ
o6 : Ideal of --[f ..f ]
               5  0   5

i7 : coefficientRing ring I

     ZZ
o7 = --
      5

o7 : QuotientRing

Ways to use idealOrlikSolomonAlgebra:

idealOrlikSolomonAlgebra(Matroid)

For the programmer

The object idealOrlikSolomonAlgebra is a method function with options.

The source of this document is in Matroids/doc-Matroids.m2:3054:0.

idealOrlikSolomonAlgebra -- the defining ideal of the Orlik-Solomon algebra

Description

See also

Ways to use idealOrlikSolomonAlgebra:

For the programmer