isLocallyFree -- whether a coherent sheaf is locally free

Usage:

isLocallyFree F
Inputs:
- F, a sum of twists, a sheaf of rings, or a coherent sheaf,
Outputs:
- a Boolean value,

Description

This method determines whether a coherent sheaf $\mathcal F$ on $X$ is locally free; i.e. there is an open cover of $X$ such that $\mathcal F(U)$ for each patch $U\subset X$ is a free $\mathcal O_X(U)$-module.

i1 : X = Proj QQ[x,y,z]

o1 = X

o1 : ProjectiveVariety

i2 : isLocallyFree OO_X

o2 = true

i3 : isLocallyFree OO_X^{1,2,3}

o3 = true

i4 : F = cotangentSheaf X

o4 = cokernel {2} | z  |
              {2} | x  |
              {2} | -y |

                                         3
o4 : coherent sheaf on X, quotient of OO  (-2)
                                        X

i5 : isLocallyFree F

o5 = true

Internally, the algorithm uses a computation of fitting ideals.

Code

../../../../Macaulay2/packages/Varieties.m2:697:31-701:64: --source code:
isLocallyFree CoherentSheaf := F -> (
    if (d := rank F) == 0 then return F == 0;
    if isFreeModule module F then return true;
    dim fittingIdeal(d,   module F) <= 0
    and fittingIdeal(d-1, module F) == ideal 0_(ring variety F))

Ways to use isLocallyFree:

isLocallyFree(CoherentSheaf)
isLocallyFree(SheafOfRings)
isLocallyFree(SumOfTwists)

For the programmer

The object isLocallyFree is a method function.

The source of this document is in Varieties/doc-sheaves.m2:624:0.

isLocallyFree -- whether a coherent sheaf is locally free

Description

Code

See also

Ways to use isLocallyFree:

For the programmer