boundaryMap(ZZ,CellComplex) -- compute the boundary map of a cell complex from r-faces to (r-1)-faces

Synopsis

Function: boundaryMap
Usage:

boundaryMap(ZZ,CellComplex)
Inputs:
- r, an integer, the source cell-dimension
- C, a cell complex, the CellComplex
Optional inputs:
- Labels => ..., default value {},
Outputs:
- a matrix, the boundary map from r-faces to (r-1)-faces of C

This function returns the map in the chain complex from the r-th homological degree to the (r-1)-th homological degree.

For example, below we construct the Taylor complex for the monomial ideal $\langle x,y,z\rangle$

i1 : R = QQ[x,y,z];

i2 : vx = newSimplexCell({},x);

i3 : vy = newSimplexCell({},y);

i4 : vz = newSimplexCell({},z);

i5 : exy = newSimplexCell {vx,vy};

i6 : exz = newSimplexCell {vx,vz};

i7 : eyz = newSimplexCell {vy,vz};

i8 : f = newSimplexCell {exy,exz,eyz};

i9 : C = cellComplex(R,{f});

i10 : d1 = boundaryMap_1 C

o10 = {1} | y  0  z  |
      {1} | -x z  0  |
      {1} | 0  -y -x |

o10 : Matrix

i11 : d2 = boundaryMap_2 C

o11 = {2} | z  |
      {2} | x  |
      {2} | -y |

o11 : Matrix

i12 : assert(d1*d2==0)