map(Complex,Complex,ZZ) -- make the zero map or identity between chain complexes

Synopsis

Function: map
Usage:

f = map(D, C, 0)

f = map(C, C, 1)
Inputs:
- C, a complex,
- D, a complex,
- 0, an integer, or 1
Optional inputs:
- Degree => an integer, default value null, the degree of the resulting map
- DegreeLift => ..., default value null, unused
- DegreeMap => ..., default value null, unused
Outputs:
- f, a map of complexes, the zero map from $C$ to $D$ or the identity map from $C$ to $C$

Description

A map of complexes $f : C \rightarrow D$ of degree $d$ is a sequence of maps $f_i : C_i \rightarrow D_{d+i}$.

We construct the zero map between two chain complexes.

i1 : R = QQ[a,b,c]

o1 = R

o1 : PolynomialRing

i2 : C = freeResolution coker vars R

      1      3      3      1
o2 = R  <-- R  <-- R  <-- R
                           
     0      1      2      3

o2 : Complex

i3 : D = freeResolution coker matrix{{a^2, b^2, c^2}}

      1      3      3      1
o3 = R  <-- R  <-- R  <-- R
                           
     0      1      2      3

o3 : Complex

i4 : f = map(D, C, 0)

o4 = 0

o4 : ComplexMap

i5 : assert isWellDefined f

i6 : assert isComplexMorphism f

i7 : g = map(C, C, 0, Degree => 13)

o7 = 0

o7 : ComplexMap

i8 : assert isWellDefined g

i9 : assert(degree g == 13)

i10 : assert not isComplexMorphism g

i11 : assert isCommutative g

i12 : assert isHomogeneous g

i13 : assert(source g == C)

i14 : assert(target g == C)

Using this function to create the identity map is the same as using id _ Complex.

i15 : assert(map(C, C, 1) === id_C)

Ways to use this method: