HomotopyLieAlgebra -- Homotopy Lie Algebra of a surjective ring homomorphism

Description

If R = S/I, K is the Koszul complex on the generators of I, and A is the DGAlgebra that is the acyclic closure of K, then the homotopy Lie algebra Pi of the map S -->> R is defined as in Briggs ****, with underlying vector space the graded dual of the space spanned by a given set of generators of A.

i1 : S = ZZ/101[x,y]

o1 = S

o1 : PolynomialRing

i2 : R = S/ideal(x^2,y^2,x*y)

o2 = R

o2 : QuotientRing

i3 : KR = koszulComplexDGA(ideal R)

o3 = {Ring => S                      }
      Underlying algebra => S[T ..T ]
                               1   3
                        2   2
      Differential => {x , y , x*y}

o3 : DGAlgebra

Since the acyclic closure is infinitely generated, we must specify the maximum homological degree in which cycles will be killed

i4 : lastCyclesDegree = 4

o4 = 4

i5 : A = acyclicClosure(KR, EndDegree => lastCyclesDegree)

o5 = {Ring => S                                                                                                                                                                                                                                                                                                                                                                                                                                                           }
      Underlying algebra => S[T ..T  ]
                               1   25
                        2   2                                                                                                                                                                                                                 2                                   2                                                                           2                                                                          2
      Differential => {x , y , x*y, x*T  - y*T , - y*T  + x*T , T T  + y*T , - T T  + x*T  + y*T , - T T  + x*T , - T T  + y*T , - T T  + x*T , - T T  - T T  + y*T , - T T  - T T  + x*T , - T T  + y*T , - T T  + x*T , - T T  + y*T , - 50T  - T T  + x*T , - T T  + y*T  , 50T  - T T  + y*T  , T T  + x*T   - y*T  , - T T  - T T  + x*T   + y*T  , - 50T  - T T  + x*T  , - T T  - T T  - T T  + y*T   + y*T  , - T T  + x*T  , 50T  - T T  + y*T  , - T T  + x*T  }
                                       2      3       1      3   2 3      4     1 2      4      5     1 3      5     2 4      6     3 4      6     3 4    2 5      7     1 4    3 5      7     3 5      8     1 5      8     2 6      9       4    3 6      9     3 6      10     4    2 7      11   4 5      11      12     1 6    3 7      10      12       5    1 7      12     4 5    3 7    2 8      12      13     3 8      13     5    3 8      14     1 8      14

o5 : DGAlgebra

The evaluation of bracketMatrix(A,d,e) gives the matrix of values of [Pi^d,Pi^e]. Here we are identifying the vector space spanned by the generators of A with its graded dual by taking the generators produced by the algorithm in the DGAlgebras package to be self-dual.

i6 : bracketMatrix(A,1,1)

o6 = | 2T_1 T_3  |
     | T_3  2T_2 |

                        2                 2
o6 : Matrix (S[T ..T  ])  <-- (S[T ..T  ])
                1   25            1   25

i7 : bracketMatrix(A,2,1)

o7 = | 0   -T_5 |
     | T_4 0    |
     | T_5 -T_4 |

                        3                 2
o7 : Matrix (S[T ..T  ])  <-- (S[T ..T  ])
                1   25            1   25

i8 : bracketMatrix(A,2,2)

o8 = | 0   -T_7 -T_8 |
     | T_7 0    T_6  |
     | T_8 -T_6 0    |

                        3                 3
o8 : Matrix (S[T ..T  ])  <-- (S[T ..T  ])
                1   25            1   25

Note that bracketMatrix(A,d,e) is antisymmetric in d,e if one of them is even, and symmetric in d,e if both are odd

i9 : bracketMatrix(A,1,1) - transpose bracketMatrix(A,1,1)

o9 = 0

                        2                 2
o9 : Matrix (S[T ..T  ])  <-- (S[T ..T  ])
                1   25            1   25

i10 : bracketMatrix(A,2,1) + transpose bracketMatrix(A,1,2)

o10 = 0

                         3                 2
o10 : Matrix (S[T ..T  ])  <-- (S[T ..T  ])
                 1   25            1   25

References

Briggs, Avramov

Author

David Eisenbud <[email protected]>

Version

This documentation describes version 0.9 of HomotopyLieAlgebra.

Citation

If you have used this package in your research, please cite it as follows:

@misc{HomotopyLieAlgebraSource,
  title = {{HomotopyLieAlgebra: A \emph{Macaulay2} package. Version~0.9}},
  author = {David Eisenbud},
  howpublished = {A \emph{Macaulay2} package available at
    \url{https://github.com/Macaulay2/M2/tree/master/M2/Macaulay2/packages}}
}

Exports

Functions and commands
- ad -- matrix of the adjoint action
- allgens -- List the generators of a given degree
- bracket -- Computes the Lie product
- bracketMatrix -- Multiplication matrix of the homotopy Lie algebra
Methods
- ad(DGAlgebra,RingElement,ZZ) -- see ad -- matrix of the adjoint action
- allgens(DGAlgebra) -- see allgens -- List the generators of a given degree
- allgens(DGAlgebra,ZZ) -- see allgens -- List the generators of a given degree
- bracket(DGAlgebra,List) -- see bracket -- Computes the Lie product
- bracket(DGAlgebra,List,RingElement) -- see bracket -- Computes the Lie product
- bracket(DGAlgebra,ZZ,ZZ) -- see bracket -- Computes the Lie product
- bracketMatrix(DGAlgebra,ZZ,ZZ) -- see bracketMatrix -- Multiplication matrix of the homotopy Lie algebra

For the programmer

The object HomotopyLieAlgebra is a package, defined in HomotopyLieAlgebra.m2.

The source of this document is in HomotopyLieAlgebra.m2:283:0.