minors(ZZ,Matrix) -- ideal generated by minors

• Function: minors

• Usage:

  minors(n,M)

• Inputs:
  • n, an integer, order of the minor
  • M, a matrix, a map between free modules
• Optional inputs:
  • First => a list, default value null, if given, should be a list of two integer lists, which will be the first minor computed
  • Limit => an integer, default value infinity, the maximum number of minors to find
  • Strategy => ..., default value null, choose between Bareiss, Cofactor and Dynamic algorithms
• Outputs:
  • an ideal, the ideal generated by the n by n minors of the matrix M

i1 : R = ZZ[a..f];

i2 : M = matrix{{a,b,c},{d,e,f}}

o2 = | a b c |
     | d e f |

             2      3
o2 : Matrix R  <-- R

i3 : minors(2,M)

o3 = ideal (- b*d + a*e, - c*d + a*f, - c*e + b*f)

o3 : Ideal of R

i4 : minors(2,M,Limit=>1)

o4 = ideal(- b*d + a*e)

o4 : Ideal of R

i5 : minors(1,M)

o5 = ideal (a, d, b, e, c, f)

o5 : Ideal of R

i6 : minors(0,M)

o6 = ideal 1

o6 : Ideal of R

i7 : minors(-1,M)

o7 = ideal 1

o7 : Ideal of R