maxGrading -- computes the maximal $\mathbb{Z}^k$ grading such that $\ker(F)$ is homogeneous

Synopsis

Usage:

maxGrading(F)
Inputs:
- F, a ring map,
Optional inputs:
- ReturnTargetGrading => a Boolean value, default value false, a boolean which encodes whether or not to also return the grading on target(F) which induces the grading on $\ker(F)$
Outputs:
- a matrix, the maximal $\mathbb{Z}^k$ grading in which $\ker(F)$ is homogeneous

Description

Computes the maximal $\mathbb{Z}^k$ grading such that the $\ker(F)$ is homogeneous. The columns of the output matrix are the degrees of the corresponding variables in source(F). For example, the snippet below shows that the maximal grading of a toric ideal is exactly the integer matrix which encodes the monomial map parameterizing the ideal.

i1 : A = matrix {{1,1,1,0,0,0}, {0,0,0,1,1,1}, {1,0,0,1,0,0}, {0,1,0,0,1,0}, {0,0,1,0,0,1}}

o1 = | 1 1 1 0 0 0 |
     | 0 0 0 1 1 1 |
     | 1 0 0 1 0 0 |
     | 0 1 0 0 1 0 |
     | 0 0 1 0 0 1 |

              5       6
o1 : Matrix ZZ  <-- ZZ

i2 : R = QQ[x_(1,1)..x_(2,3)];

i3 : S = QQ[t_1..t_2, s_1..s_3];

i4 : F = map(S, R, {t_1*s_1, t_1*s_2, t_1*s_3, t_2*s_1, t_2*s_2, t_2*s_3})

o4 = map (S, R, {t s , t s , t s , t s , t s , t s })
                  1 1   1 2   1 3   2 1   2 2   2 3

o4 : RingMap S <-- R

i5 : maxGrading(F)

o5 = | 1 1 1 0 0 0 |
     | 0 0 0 1 1 1 |
     | 1 0 0 1 0 0 |
     | 0 1 0 0 1 0 |
     | 0 0 1 0 0 1 |

              5       6
o5 : Matrix ZZ  <-- ZZ

The option ReturnTargetGrading returns a matrix which also gives the corresponding grading on the target ring of $F$ which induces the grading on $\ker(F)$. This option is false by default.

i6 : maxGrading(F, ReturnTargetGrading => true)

o6 = | 1 1 1 0 0 0 1 0 0 0 0 |
     | 0 0 0 1 1 1 0 1 0 0 0 |
     | 1 0 0 1 0 0 0 0 1 0 0 |
     | 0 1 0 0 1 0 0 0 0 1 0 |
     | 0 0 1 0 0 1 0 0 0 0 1 |

              5       11
o6 : Matrix ZZ  <-- ZZ

Ways to use maxGrading:

maxGrading(RingMap)

For the programmer

The object maxGrading is a method function with options.