isLocallyFree -- checks whether a toric reflexive sheaf is locally free

Synopsis

Usage:

isLF = isLocallyFree E
Inputs:
- E, a vector bundle on a toric variety (Klyachko's description)
Outputs:
- isLF, a Boolean value, true if the reflexive sheaf is locally free, false otherwise
Consequences:
- The result of isLocallyFree will be stored as a cacheValue in E.cache#isLF.

Description

Contrary to what the name suggests, ToricVectorBundle may well encode a toric reflexive sheaf that is not locally free. isLocallyFree permits to check whether a toric reflexive sheaf is locally free, that is, locally a direct sum of invertible sheaves, that is, a vector bundle.
isLocallyFree calls internally the methods isLocallyWeil and toricChernCharacter.

i1 : A3 = fan coneFromVData matrix {{1,0,0},{0,1,0},{0,0,1}};

i2 : filtMat = apply( { {{1,0},{0,1}}, {{0,1},{1,0}}, {{1,1},{1,0}} }, matrix);

i3 : filtStep = apply( { {{0,1}}, {{0,1}}, {{0,1}} }, matrix);

i4 : E = toricVectorBundle (2,A3,filtMat,filtStep);

i5 : details E

o5 = HashTable{| 0 | => (| 1 0 |, | 0 1 |)}
               | 0 |     | 0 1 |
               | 1 |
               | 0 | => (| 0 1 |, | 0 1 |)
               | 1 |     | 1 0 |
               | 0 |
               | 1 | => (| 1 1 |, | 0 1 |)
               | 0 |     | 1 0 |
               | 0 |

o5 : HashTable

i6 : isLocallyFree E

o6 = false

i7 : P112 = ccRefinement transpose matrix {{1,0},{0,1},{-1,-2}};

i8 : D = {1,0,0};

i9 : L = toricVectorBundle(1, P112, toList(3: matrix{{1_QQ}}), apply( D, i-> matrix{{-i}}));

i10 : details L

o10 = HashTable{| -1 | => (| 1 |, | -1 |)}
                | -2 |
                | 0 | => (| 1 |, 0)
                | 1 |
                | 1 | => (| 1 |, 0)
                | 0 |

o10 : HashTable

i11 : isLocallyWeil L

o11 = true

i12 : toricChernCharacter L

o12 = HashTable{| -1 0 | => {| 1 |}  }
                | -2 1 |     | 0 |
                | 1 -1 | => {| 0   |}
                | 0 -2 |     | 1/2 |
                | 1 0 | => {0}
                | 0 1 |

o12 : HashTable

i13 : isLocallyFree L

o13 = false

Caveat

This method works for any toric reflexive sheaf on a toric variety, whose fan is covered by cones of maximal dimension.

Ways to use isLocallyFree:

isLocallyFree(ToricVectorBundleKlyachko)

For the programmer

The object isLocallyFree is a method function.