Macaulay2 » Documentation
Packages » TestIdeals :: frobenius
next | previous | forward | backward | up | index | toc

frobenius -- compute a Frobenius power of an ideal or a matrix

Synopsis

Description

Given an ideal $I$ in a ring of characteristic $p > 0$ and a nonnegative integer $e$, frobenius(e, I) or frobenius^e(I) returns the $p^e$-th Frobenius power $I^{[p^e]}$, that is, the ideal generated by all powers $f^{ p^e}$, with $f \in\ I$ (see frobeniusPower).

i1 : R = ZZ/3[x,y];
 
i2 : I = ideal(x^2, x*y, y^2);

o2 : Ideal of R
 
i3 : frobenius(2, I)

             18   9 9   18
o3 = ideal (x  , x y , y  )

o3 : Ideal of R
 
i4 : frobenius^2(I)

             18   9 9   18
o4 = ideal (x  , x y , y  )

o4 : Ideal of R
 
i5 : frobeniusPower(3^2, I)

             18   9 9   18
o5 = ideal (x  , x y , y  )

o5 : Ideal of R

If $e$ is negative, then frobenius(e, I) or frobenius^e(I) computes a Frobenius root, as defined by Blickle, Mustata, and Smith (see frobeniusRoot).

i6 : R = ZZ/5[x,y,z,w];
 
i7 : I = ideal(x^27*y^10 + 3*z^28 - x^2*y^15*z^35, x^17*w^30 + 2*x^10*y^10*z^35, x*z^50);

o7 : Ideal of R
 
i8 : frobenius(-1, I)

             5   5 2   3 6
o8 = ideal (z , x y , x w )

o8 : Ideal of R
 
i9 : frobenius(-2, I)

o9 = ideal (w, z, x)

o9 : Ideal of R
 
i10 : frobeniusRoot(2, I)

o10 = ideal (w, z, x)

o10 : Ideal of R

If $M$ is a matrix with entries in a ring of characteristic $p > 0$ and $e$ is a nonnegative integer, then frobenius(e, M), or frobenius^e(M), outputs a matrix whose entries are the $p^e$-th powers of the entries of $M$.

i11 : R = ZZ/3[x,y];
 
i12 : M = matrix {{x, y},{x + y, x^2 + y^2}};

              2      2
o12 : Matrix R  <-- R
 
i13 : frobenius(2, M)

o13 = | x9    y9      |
      | x9+y9 x18+y18 |

              2      2
o13 : Matrix R  <-- R

frobenius(I) and frobenius(M) are abbreviations for frobenius(1, I) and frobenius(1, M).

See also

For the programmer

The object frobenius is an instance of the type FrobeniusOperator.