toricQuiver -- the toricQuiver constructor

Usage:

Q = toricQuiver E

Q = toricQuiver (E, F)

Q = toricQuiver M

Q = toricQuiver (M, F)

Q = toricQuiver G

Q = toricQuiver (G, F)

Q = toricQuiver T

Q = toricQuiver (T, F)
Inputs:
- E, a list, of pairs (V1, V2) giving the edges of the quiver in terms of the vertices
- F, a list, the flow on the quiver given as a list of integers
- G, a graph,
- M, a matrix, of integers giving the connectivity structure of the quiver. If specified, this matrix should be a well-defined incidence matrix for the graph underlying the quiver
- T, a toric quiver,
Optional inputs:
- Flow => a string, default value "Default", that specifies the flow for the polytope. options are Default, which takes the flow from values in the matrix, Canonical, which sets the flow to 1 for each edge, and Random, which assigns a random integer between 0 and Height to each edge
- Height => an integer, default value 10, used in conjunction with the option Flow => Random to set the upper limit of the random number generator
Outputs:
- Q, a toric quiver,

Description

A toric quiver is a directed graph Q=(Q_0, Q_1) where Q_0 is the set of vertices associated to Q and Q_1 is the set of arrows. Also included in $Q$ is a flow, which associates an integer value to each edge. The canonical flow gives a weight of 1 to each edge.

The ToricQuiver data type is stored as a hash table with the following keys:

IncidenceMatrix:matrix representation of the connected graph underlying the quiver
flow: list of integers representing the flow associated to each edge of the quiver
Q0: the list of vertices
Q1: the list of edges
weights: the values on each vertex induced by the flow

i1 : Q = toricQuiver matrix({{-1,-1,-1,-1},{1,1,0,0},{0,0,1,1}})

o1 = ToricQuiver{flow => {1, 1, 1, 1}                  }
                 IncidenceMatrix => | -1 -1 -1 -1 |
                                    | 1  1  0  0  |
                                    | 0  0  1  1  |
                 Q0 => {0, 1, 2}
                 Q1 => {{0, 1}, {0, 1}, {0, 2}, {0, 2}}
                 weights => {-4, 2, 2}

o1 : ToricQuiver

i2 : Q = toricQuiver(matrix({{-1,-1,-1,-1},{1,1,0,0},{0,0,1,1}}), {3, 1, 0, 5})

o2 = ToricQuiver{flow => {3, 1, 0, 5}                  }
                 IncidenceMatrix => | -1 -1 -1 -1 |
                                    | 1  1  0  0  |
                                    | 0  0  1  1  |
                 Q0 => {0, 1, 2}
                 Q1 => {{0, 1}, {0, 1}, {0, 2}, {0, 2}}
                 weights => {-9, 4, 5}

o2 : ToricQuiver

i3 : Q = toricQuiver {{0,1},{0,1},{0,2},{0,2}}

o3 = ToricQuiver{flow => {1, 1, 1, 1}                  }
                 IncidenceMatrix => | -1 -1 -1 -1 |
                                    | 1  1  0  0  |
                                    | 0  0  1  1  |
                 Q0 => {0, 1, 2}
                 Q1 => {{0, 1}, {0, 1}, {0, 2}, {0, 2}}
                 weights => {-4, 2, 2}

o3 : ToricQuiver

i4 : Q = toricQuiver ({{0,1},{0,1},{0,2},{0,2}}, {1,2,3,4})

o4 = ToricQuiver{flow => {1, 2, 3, 4}                  }
                 IncidenceMatrix => | -1 -1 -1 -1 |
                                    | 1  1  0  0  |
                                    | 0  0  1  1  |
                 Q0 => {0, 1, 2}
                 Q1 => {{0, 1}, {0, 1}, {0, 2}, {0, 2}}
                 weights => {-10, 3, 7}

o4 : ToricQuiver

i5 : Q = toricQuiver(matrix({{-1,-1,-1,-1},{1,1,0,0},{0,0,1,1}}), Flow => "Canonical")

o5 = ToricQuiver{flow => {1, 1, 1, 1}                  }
                 IncidenceMatrix => | -1 -1 -1 -1 |
                                    | 1  1  0  0  |
                                    | 0  0  1  1  |
                 Q0 => {0, 1, 2}
                 Q1 => {{0, 1}, {0, 1}, {0, 2}, {0, 2}}
                 weights => {-4, 2, 2}

o5 : ToricQuiver

i6 : Q = toricQuiver(matrix({{-1,-1,-1,-1},{0,0,1,1},{1,1,0,0}}), Flow => "Random")

o6 = ToricQuiver{flow => {3, 7, 8, 1}                  }
                 IncidenceMatrix => | -1 -1 -1 -1 |
                                    | 1  1  0  0  |
                                    | 0  0  1  1  |
                 Q0 => {0, 1, 2}
                 Q1 => {{0, 1}, {0, 1}, {0, 2}, {0, 2}}
                 weights => {-19, 10, 9}

o6 : ToricQuiver

i7 : Q = toricQuiver(matrix({{-1,-1,-1,-1},{0,0,1,1},{1,1,0,0}}), Flow => "Random", Height => 201)

o7 = ToricQuiver{flow => {19, 19, 72, 122}             }
                 IncidenceMatrix => | -1 -1 -1 -1 |
                                    | 1  1  0  0  |
                                    | 0  0  1  1  |
                 Q0 => {0, 1, 2}
                 Q1 => {{0, 1}, {0, 1}, {0, 2}, {0, 2}}
                 weights => {-232, 38, 194}

o7 : ToricQuiver

i8 : Q = toricQuiver(matrix({{-1,-1,-1,-1},{0,0,1,1},{1,1,0,0}}), Flow => "Random");

i9 : R = toricQuiver(Q)

o9 = ToricQuiver{flow => {8, 5, 7, 8}                  }
                 IncidenceMatrix => | -1 -1 -1 -1 |
                                    | 1  1  0  0  |
                                    | 0  0  1  1  |
                 Q0 => {0, 1, 2}
                 Q1 => {{0, 1}, {0, 1}, {0, 2}, {0, 2}}
                 weights => {-28, 13, 15}

o9 : ToricQuiver

i10 : R = toricQuiver(Q, {1,2,3,4})

o10 = ToricQuiver{flow => {1, 2, 3, 4}                  }
                  IncidenceMatrix => | -1 -1 -1 -1 |
                                     | 1  1  0  0  |
                                     | 0  0  1  1  |
                  Q0 => {0, 1, 2}
                  Q1 => {{0, 1}, {0, 1}, {0, 2}, {0, 2}}
                  weights => {-10, 3, 7}

o10 : ToricQuiver

Ways to use toricQuiver:

toricQuiver(List)
toricQuiver(List,List)
toricQuiver(Matrix)
toricQuiver(Matrix,List)
toricQuiver(ToricQuiver)
toricQuiver(ToricQuiver,List)

For the programmer

The object toricQuiver is a method function with options.

The source of this document is in ThinSincereQuivers.m2:3279:0.

toricQuiver -- the toricQuiver constructor

Description

See also

Ways to use toricQuiver:

For the programmer