cotangentSheaf(ZZ,ProjectiveVariety) -- exterior powers of the cotangent sheaf of a projective variety

Function: cotangentSheaf
Usage:

cotangentSheaf(p, X)
Inputs:
- p, an integer,
- X, a projective variety,
Optional inputs:
- MinimalGenerators => a Boolean value, default value true, whether to prune the result before returning it
- Strategy => ..., default value null, cotangent sheaf of a projective variety
Outputs:
- a coherent sheaf,

Description

This function computes the $p$-th exterior power of the cotangent sheaf of a projective variety $X$, usually denoted $\Omega_X^p$.

As an example we compute $h^{1,1}$ on a K3 surface (a quartic in projective threespace):

i1 : K3 = Proj QQ[x_0..x_3]/(x_0^4+x_1^4+x_2^4+x_3^4-11*x_0*x_1*x_2*x_3)

o1 = K3

o1 : ProjectiveVariety

i2 : omega1 = cotangentSheaf(1, K3);

i3 : HH^1(omega1)

       20
o3 = QQ

o3 : QQ-module, free

As a second example we compute Hodge numbers of the Fermat quintic in projective fourspace:

i4 : FermatQuintic = Proj QQ[x_0..x_4]/(x_0^5+x_1^5+x_2^5+x_3^5+x_4^5)

o4 = FermatQuintic

o4 : ProjectiveVariety

i5 : omega1 = cotangentSheaf(1, FermatQuintic);

i6 : HH^1(omega1)

       1
o6 = QQ

o6 : QQ-module, free

i7 : HH^2(omega1)

       101
o7 = QQ

o7 : QQ-module, free

i8 : omega2 = cotangentSheaf(2, FermatQuintic);

i9 : HH^1(omega2)

       101
o9 = QQ

o9 : QQ-module, free

i10 : HH^2(omega2)

        1
o10 = QQ

o10 : QQ-module, free

cotangentSheaf(ZZ,ProjectiveVariety) -- exterior powers of the cotangent sheaf of a projective variety

The source of this document is in Varieties/doc-sheaves.m2:501:0.