Macaulay2 » Documentation
Packages » AssociativeAlgebras :: nakayamaAut
next | previous | forward | backward | up | index | toc

nakayamaAut -- Computes the Nakayama automorphism using the superpotential

Description

This function uses the superpotential to compute the Nakayama automorphism of an m-Koszul AS regular algebra B. For example, the Nakayama automorphism of the commutative polynomial ring is trivial: As a Groebner basis may need to be performed, one may pass the strategy as an optional argument. Here, the "Naive" strategy is used here as the default Groebner basis strategy is not compatible with coefficients not over the rationals, so passing this option helps suppress certain warnings.

i1 : kk = QQ

o1 = QQ

o1 : Ring
 
i2 : R = skewPolynomialRing(kk,1_kk,{x,y,z})

o2 = R

o2 : FreeAlgebraQuotient
 
i3 : nak = nakayamaAut(R, Strategy => "Naive")

o3 = map (R, R, {x, y, z})

o3 : RingMap R <-- R

In contrast, the Nakayama automorphism of a skew polynomial ring is given in terms of the skewing parameters:

i4 : ll = frac(QQ[a,b,c])

o4 = ll

o4 : FractionField
 
i5 : M = matrix {{1,a,b},{a^(-1),1,c},{b^(-1),c^(-1),1}}

o5 = | 1   a   b |
     | 1/a 1   c |
     | 1/b 1/c 1 |

              3       3
o5 : Matrix ll  <-- ll
 
i6 : S = skewPolynomialRing(ll,M,{x,y,z})

o6 = S

o6 : FreeAlgebraQuotient
 
i7 : nak2 = nakayamaAut(S, Strategy => "Naive")

                  1     a
o7 = map (S, S, {---*x, -*y, b*c*z, a, b, c})
                 a*b    c

o7 : RingMap S <-- S

One may also find the Nakayama automorphism corresponding to a twisted superpotential, although this will give a ring map on the ambient tensor product rather than the quotient.

i8 : wR = superpotential(R, Strategy => "Naive")

o8 = - x*y*z + x*z*y + y*x*z - y*z*x - z*x*y + z*y*x

o8 : QQ <|x, y, z|>
 
i9 : A = ambient R

o9 = A

o9 : FreeAlgebra
 
i10 : nak3 = nakayamaAut wR

o10 = map (A, A, {x, y, z})

o10 : RingMap A <-- A

See also

Ways to use nakayamaAut:

  • nakayamaAut(FreeAlgebraQuotient)
  • nakayamaAut(RingElement)

For the programmer

The object nakayamaAut is a method function with options.

The source of this document is in AssociativeAlgebras/doc.m2:1741:0.