Hom -- module of homomorphisms

Usage:

Hom(M, N)
Inputs:
- M, a ring, an ideal, or a module,
- N, a ring, an ideal, or a module,
Optional inputs:
- DegreeLimit => an integer or a list, default value null, if set, stop after homomorphisms in this degree have been computed
- MinimalGenerators => a Boolean value, default value true, whether to trim the resulting module
- Strategy => a thing, default value null
Outputs:
- a module, isomorphic to $\mathrm{Hom}_R(M,N), where $M$ and $N$ are both $R$-modules

Description

If $M$ or $N$ is an ideal or ring, it is regarded as a module in the evident way.

i1 : R = QQ[x,y]/(y^2 - x^3);

i2 : M = image matrix{{x, y}}

o2 = image | x y |

                             1
o2 : R-module, submodule of R

i3 : H = Hom(M, M, MinimalGenerators => true)

o3 = image {-1} | x y  |
           {-1} | y x2 |

                             2
o3 : R-module, submodule of R

To recover the modules used to create a Hom-module, use the function formation.

i4 : formation H

o4 = Hom (image | x y |, image | x y |, DegreeLimit => null)

o4 : Expression of class FunctionApplication

Specific homomorphisms may be obtained using homomorphism, as follows.

i5 : f0 = homomorphism H_{0}

o5 = {1} | 1 0 |
     {1} | 0 1 |

o5 : Matrix M <-- M

i6 : f1 = homomorphism H_{1}

o6 = {1} | 0 x |
     {1} | 1 0 |

o6 : Matrix M <-- M

In the example above, f0 is the identity map, and f1 maps $x$ to $y$ and $y$ to $x^2$.

i7 : M_0, M_1

o7 = (| x |, | y |)

o7 : Sequence

i8 : f0 M_0, f0 M_1

o8 = (| x |, | y |)

o8 : Sequence

i9 : f1 M_0, f1 M_1

o9 = (| y |, | x2 |)

o9 : Sequence

Contributors

Devlin Mallory implemented the strategy which accepts a degree limit.

Ways to use Hom:

Hom(Ideal,Ideal)
Hom(Ideal,Module)
Hom(Ideal,Ring)
Hom(Module,Ideal)
Hom(Module,Module)
Hom(Module,Ring)
Hom(Ring,Ideal)
Hom(Ring,Module)
Hom(Ring,Ring)
Hom(Matrix,Matrix) -- see Hom(Module,Matrix) -- induced map on Hom
Hom(Matrix,Module) -- see Hom(Module,Matrix) -- induced map on Hom
Hom(Module,Matrix) -- induced map on Hom

For the programmer

The object Hom is a method function with options.

The source of this document is in Macaulay2Doc/functions/Hom-doc.m2:127:0.

Hom -- module of homomorphisms

Description

Contributors

See also

Menu

Ways to use Hom:

For the programmer