betti -- display or modify a Betti diagram

The function betti creates and displays the Betti diagram of mathematical objects that can be presented using graded free modules and graded maps between them, such as ideals, modules, and chain complexes. The returned BettiTally encapsulates the data from the entries of the displayed Betti diagram, in case they are needed in a program.

The keys are triples (i,d,h) encoding:

i, the column labels, representing the homological degree;

d, a list of integers giving a multidegree; and

h, the row labels, representing the dot product of a weight covector and d.

Only i and h are used in printing, and the weight covector can be modified by specifying the betti(...,Weights=>...) option. The heft vector of the ring of the input object is the default choice for the weight covector.

If the ring has no heft vector, then the weights vector is taken to be all zero. If the option betti(...,Weights=>...) is provided, the length of the given weight vector should be the same as the degree length of the ring of the input object.

If the ring is multigraded, the function multigraded(BettiTally) may be used to extract information from all degree components of the Betti diagram at once.

Betti table of a Gröbner basis

• Usage:

  betti G

• Inputs:
  • G, a Gröbner basis,
  • Weights => ...
• Outputs:
  • a Betti tally, a diagram showing the degrees of the generators of the source and target modules of the matrix of generators of G

i16 : S = ZZ/10007[x,y];

i17 : G = gb ideal(x^3+y^3, x*y^4);

i18 : gens G

o18 = | x3+y3 xy4 y7 |

              1      3
o18 : Matrix S  <-- S

i19 : betti G

             0 1
o19 = total: 1 3
          0: 1 .
          1: . .
          2: . 1
          3: . .
          4: . 1
          5: . .
          6: . 1

o19 : BettiTally

Betti diagram showing the degrees of the target and source of a map

• Usage:

  betti f

• Inputs:
  • f, a matrix,
  • Weights => ...
• Outputs:
  • a Betti tally, a diagram showing the degrees of the generators of the source and target modules of f

i20 : S = ZZ/10007[x,y];

i21 : betti matrix {{x^3, x*y^2}, {y*x, y^2}}

             0 1
o21 = total: 2 2
          0: 2 .
          1: . .
          2: . 2

o21 : BettiTally

Betti diagram showing the degrees of generators and relations of a homogeneous module

• Usage:

  betti M

• Inputs:
  • M, a module,
  • Weights => ...
• Outputs:
  • a Betti tally, showing the zero-th, first graded, and total Betti numbers of $M$.

i22 : S = ZZ/10007[x,y];

i23 : betti coker matrix{{x^3, x*y^2}, {y*x^2, y^3}}

             0 1
o23 = total: 2 2
          0: 2 .
          1: . .
          2: . 2

o23 : BettiTally

i24 : betti coker map(S^{0,-1}, , matrix{{x^2, y}, {y^3, x^2}})

             0 1
o24 = total: 2 2
          0: 1 .
          1: 1 .
          2: . 1
          3: . 1

o24 : BettiTally

Betti diagram showing the degrees of generators of a homogeneous ideal

• Usage:

  betti I

• Inputs:
  • I, an ideal,
  • Weights => ...
• Outputs:
  • a Betti tally, showing the degrees of the generators and relations of the quotient of the ambient ring by $I$

i25 : S = ZZ/10007[x,y];

i26 : I = ideal(x,x^2,y^3);

o26 : Ideal of S

i27 : betti I

             0 1
o27 = total: 1 3
          0: 1 1
          1: . 1
          2: . 1

o27 : BettiTally

i28 : betti comodule I

             0 1
o28 = total: 1 3
          0: 1 1
          1: . 1
          2: . 1

o28 : BettiTally