gb -- compute a Gröbner basis

• Usage:

  gb I

• Inputs:
  • I, an ideal, module, or matrix
• Optional inputs:
  • Algorithm => a symbol, default value Inhomogeneous, possible values: Homogeneous, Inhomogeneous, Homogeneous2, and Sugarless. Experimental options include LinearAlgebra and Toric.
  • BasisElementLimit => an integer, default value infinity, stop when this number of (nonminimal) Gröbner basis elements has been found
  • ChangeMatrix => a Boolean value, default value false, whether to compute the change of basis matrix from Gröbner basis elements to original generators. Use getChangeMatrix to recover it.
  • CodimensionLimit => an integer, default value infinity, stop computation once codimension of submodule of lead terms reaches this value (not functional yet)
  • DegreeLimit => a list, default value {}, stop after the Gröbner basis in this degree has been computed
  • GBDegrees => a list, default value null, a list of positive integer weights, one for each variable in the ring, to be used for organizing the computation by degrees (the 'sugar' ecart vector)
  • HardDegreeLimit => ..., default value null, throws away all S-pairs of degrees beyond the limit. The computation will be re-initialized if higher degrees are required.
  • Hilbert => ..., default value null, informs Macaulay2 that this is the poincare polynomial, and can be used to aid in the computation of the Gröbner basis (Hilbert driven)
  • MaxReductionCount => an integer, default value 10, the maximum number of reductions of an S-pair done before requeueing it, if the Inhomogeneous algorithm is in use
  • PairLimit => an integer, default value infinity, stop after this number of spairs has been considered
  • StopBeforeComputation => a Boolean value, default value false, whether to initialize the Gröbner basis engine but return before doing any computation (useful for using or viewing partially computed Gröbner bases)
  • StopWithMinimalGenerators => a Boolean value, default value false, whether to stop as soon as the minimal set (or a trimmed set, if not homogeneous or local) of generators is known. Intended for internal use only
  • Strategy => ..., default value {}, either LongPolynomial, Sort (missing documentation) , or a list of these. LongPolynomial: use a geobucket data structure while reducing polynomials; Sort: sort the S-pairs by lead term (usually this is a bad idea). Another symbol usable here is UseSyzygies. Usually S-pairs are processed degree by degree in the order that they were constructed.
  • SubringLimit => an integer, default value infinity, stop after this number of elements of the Gröbner basis lie in the first subring
  • Syzygies => a Boolean value, default value false, whether to collect syzygies on the original generators during the computation. Intended for internal use only
  • SyzygyLimit => an integer, default value infinity, stop when this number of non-zero syzygies has been found
  • SyzygyRows => an integer, default value infinity, for each syzygy and change of basis element, keep only this many rows of each syzygy
• Outputs:
  • a Gröbner basis, a Gröbner basis computation object

i1 : R = QQ[a..d]

o1 = R

o1 : PolynomialRing

i2 : I = ideal(a^3-b^2*c, b*c^2-c*d^2, c^3)

             3    2      2      2   3
o2 = ideal (a  - b c, b*c  - c*d , c )

o2 : Ideal of R

i3 : G = gens gb I

o3 = | c3 bc2-cd2 a3-b2c c2d2 cd4 |

             1      5
o3 : Matrix R  <-- R

i4 : R = QQ[x,y]

o4 = R

o4 : PolynomialRing

i5 : M = subquotient(matrix {{x}}, matrix {{x+y}})

o5 = subquotient (| x |, | x+y |)

                               1
o5 : R-module, subquotient of R

i6 : gens gb M

o6 = | y x |

             1      2
o6 : Matrix R  <-- R

i7 : matrix {{x}} // gb(M,ChangeMatrix=>true)

o7 = {1} | 1 |

             1      1
o7 : Matrix R  <-- R

i8 : matrix {{y}} // gb(M,ChangeMatrix=>true)

o8 = {1} | -1 |

             1      1
o8 : Matrix R  <-- R