match -- regular expression matching

Synopsis

• Usage:

  match(re, str)

  match(patterns, str)

• Inputs:
  • re, a string, a regular expression describing a pattern
  • str, a string, a subject string to be searched
  • patterns, a list, a list of regular expressions
• Optional inputs:
  • POSIX => a Boolean value, default value false, if true, interpret the re using the POSIX Extended flavor, otherwise the Perl flavor
  • Strategy => a function, default value any, logical quantifier for matching a list of patterns, typically all or any
• Outputs:
  • a Boolean value, whether the string str is a match for the regular expression re, or at least one of patterns when Strategy => any (default)
• Consequences:

  • the variable lastMatch is set to the value returned by regex which is called by match.

Description

i1 : s = "three dogs, two catfishes, and a cat"

o1 = three dogs, two catfishes, and a cat

i2 : match("cat", s)

o2 = true

i3 : lastMatch

o3 = {(16, 3)}

o3 : List

i4 : substring(first lastMatch, s)

o4 = cat

i5 : match ("cats", s)

o5 = false

i6 : lastMatch

i7 : s = "catfish cat dog"

o7 = catfish cat dog

i8 : match("cat(?!fish)", s)

o8 = true

i9 : substring(lastMatch#0#0, lastMatch#0#1 + 4, s)

o9 = cat dog

i10 : match("cat(?=fish)", s)

o10 = true

i11 : substring(lastMatch#0#0, lastMatch#0#1 + 4, s)

o11 = catfish

i12 : match("(?<!cat)fish", "cat catfish dog")

o12 = false

i13 : match("(?<!cat)fish", "cat swordfish dog")

o13 = true

i14 : match({"Cat", "Dog"}, "CatDog")

o14 = true

i15 : match({"Cat", "Dog"}, "Catfish")

o15 = true

i16 : match({"Cat", "Dog"}, "CatDog", Strategy => all)

o16 = true

i17 : not match({"Cat", "Dog"}, "Catfish", Strategy => all)

o17 = true

See also

• regular expressions -- syntax for regular expressions
• strings and nets -- an overview of strings and nets in Macaulay2
• regex -- evaluate a regular expression search
• replace -- replacement in strings and lists
• substring -- extract part of a string
• any -- whether any elements satisfy a specified condition
• all -- whether all elements satisfy a specified condition