minimalPresentation(Module) -- minimal presentation of a module

• Function: minimalPresentation

• Usage:

  N = minimalPresentation M

• Inputs:
  • M, a module
• Optional inputs:
  • Exclude => ..., default value {}, compute a minimal presentation of a quotient ring
• Outputs:
  • N, a module, isomorphic to M
• Consequences:

  • The isomorphism from N to M as g = N.cache.pruningMap unless M.cache.pruningMap already exists, in which case N is the same as M. The inverse isomorphism can be obtained as g^-1

i1 : R = ZZ/32003[a..d];

i2 : M = coker matrix {{a,1,b},{c,3,b+d}}

o2 = cokernel | a 1 b   |
              | c 3 b+d |

                            2
o2 : R-module, quotient of R

i3 : N = minimalPresentation M

o3 = cokernel | b+16001d a-10668c |

                            1
o3 : R-module, quotient of R

i4 : peek N.cache

o4 = CacheTable{cache => MutableHashTable{}}
                pruningMap => | -10668 |
                              | 0      |

i5 : g = N.cache.pruningMap

o5 = | -10668 |
     | 0      |

o5 : Matrix M <-- N

i6 : g^-1

o6 = | -3 1 |

o6 : Matrix N <-- M