monoid(...,SkewCommutative=>...) -- specify Skew commuting variables in the ring

Synopsis

• Usage:

  monoid[e_0..e_3, SkewCommutative => true]

  monoid[u,v,x,y, SkewCommutative => {u,v}]

Description

i1 : ZZ/101[e_0..e_3,       SkewCommutative => true]

      ZZ
o1 = ---[e ..e ]
     101  0   3

o1 : PolynomialRing, 4 skew commutative variable(s)

i2 : (e_0+e_1+e_2+e_3)^2

o2 = 0

      ZZ
o2 : ---[e ..e ]
     101  0   3

i3 : ZZ/101[x,y,vars(0..4), SkewCommutative => vars(0..4)]

      ZZ
o3 = ---[x..y, a..e]
     101

o3 : PolynomialRing, 5 skew commutative variable(s)

i4 : c*b*a*d

o4 = -a*b*c*d

      ZZ
o4 : ---[x..y, a..e]
     101

i5 : ZZ/101[x,y,vars(0..4), SkewCommutative => {2..6}]

      ZZ
o5 = ---[x..y, a..e]
     101

o5 : PolynomialRing, 5 skew commutative variable(s)

i6 : c*b*a*d

o6 = -a*b*c*d

      ZZ
o6 : ---[x..y, a..e]
     101

i7 : R = ZZ[x,y,z, SkewCommutative => {x,y}]

o7 = R

o7 : PolynomialRing, 2 skew commutative variable(s)

i8 : x*y

o8 = x*y

o8 : R

i9 : y*x

o9 = -x*y

o9 : R

i10 : x*z-z*x

o10 = 0

o10 : R

Further information

• Default value: {}
• Function: monoid -- make or retrieve a monoid
• Option key: SkewCommutative -- an optional argument

See also

• monoid -- make or retrieve a monoid
• newRing -- make a copy of a ring, with some features changed
• tensor(Ring,Ring) -- tensor product of monoids
• symmetricAlgebra -- the symmetric algebra of a module

Functions with optional argument named SkewCommutative :

• monoid(...,SkewCommutative=>...) -- specify Skew commuting variables in the ring
• newRing(...,SkewCommutative=>...) -- see newRing -- make a copy of a ring, with some features changed
• symmetricAlgebra(...,SkewCommutative=>...) -- see symmetricAlgebra -- the symmetric algebra of a module
• tensor(Monoid,Monoid,SkewCommutative=>...) -- see tensor(Monoid,Monoid) -- tensor product of monoids
• tensor(Ring,Ring,SkewCommutative=>...) -- see tensor(Monoid,Monoid) -- tensor product of monoids