position -- the first element of a list satisfying a condition

Usage:

position(A, f)

position(A, B, f)

position(A, f, Reverse => true)

position(n, f)
Inputs:
- A, a visible list,
- B, a visible list,
- n, an integer,
- f, a function,
Optional inputs:
- Reverse => ..., default value false
Outputs:
- p, an integer, the first index to satisfy the boolean function f

Description

position(A, f) returns the smallest index i such that f(A#i) is true. If no element satisfies the condition, null is returned.

i1 : position((10,20,43,105,6,93), odd)

o1 = 2

i2 : position((10,20,43,105,6,93), i -> i<0)

Use position(A, B, f) to return the smallest index i such that f(A#i, B#i) is true.

i3 : position((10,20,43,105,6,93),(18,82,12,7,35,92), (a,b) -> a>b)

o3 = 2

The Reverse option will return the largest index instead.

i4 : position((10,20,43,105,6,93), odd, Reverse => true)

o4 = 5

i5 : position((10,20,43,105,6,93),(18,82,12,7,35,92), (a,b) -> a>b, Reverse => true)

o5 = 5

Use position(n, f) to return the smallest index i such that f(i) is true.

i6 : position(17, i -> i^2 % 17 == 13)

o6 = 8

To find all indices of elements satisfying the condition, see positions. To return the elements, rather than their indices, see select. The function number counts the number of elements satisfying the condition.

i7 : positions((10,20,43,105,6,93), odd)

o7 = {2, 3, 5}

o7 : List

i8 : select((10,20,43,105,6,93), odd)

o8 = (43, 105, 93)

o8 : Sequence

i9 : number((10,20,43,105,6,93), odd)

o9 = 3

Ways to use position:

position(VisibleList,Function)
position(VisibleList,VisibleList,Function)
position(ZZ,Function)

For the programmer

The object position is a method function with options.

The source of this document is in Macaulay2Doc/functions/position-doc.m2:63:0.

position -- the first element of a list satisfying a condition

Description

See also

Ways to use position:

For the programmer