Fano(ZZ,EmbeddedProjectiveVariety) -- Fano scheme of a projective variety

Synopsis

Function: Fano
Usage:

Fano(k,X)

Fano(k,X,AffineChartGrass=>...)

Fano X

Fano(X,AffineChartGrass=>...)
Inputs:
- k, an integer, optional with default value equal to $\mathrm{dim}(X)$
- X, an embedded projective variety
Outputs:
- an embedded projective variety, the subvariety of the Grassmannian $\mathbb{G}(k,\mathrm{ambient}(X))$ that parametrizes the $k$-planes lying on $X$

Description

This function is based internally on the function plucker, provided by the package Resultants. In particular, note that by default the computation is done on a randomly chosen affine chart on the Grassmannian. To change this behavior, you can use the AffineChartGrass option.

i1 : K = ZZ/33331;

i2 : L = linearSpan {point PP_K^4,point PP_K^4}; -- a line in P^4

o2 : ProjectiveVariety, curve in PP^4

i3 : p := Fano L

o3 = point of coordinates [12627, 14941, 11188, -4847, 15437, 16492, 13501, 8759, 6817, 1]

o3 : ProjectiveVariety, a point in PP^9 (subvariety of codimension 6 in GG(1,4) ⊂ PP^9)

i4 : Fano p

o4 = curve in PP^4 cut out by 3 hypersurfaces of degree 1

o4 : ProjectiveVariety, curve in PP^4

i5 : assert(Fano p == L)

If the input is a subvariety $Y\subset\mathbb{G}(k,\mathbb{P}^n)$, then the output is the variety $W\subset\mathbb{P}^n$ swept out by the linear spaces corresponding to points of $Y$. As an example, we now compute a surface scroll $W\subset\mathbb{P}^4$ over an elliptic curve $Y\subset\mathbb{G}(1,\mathbb{P}^4)$.

i6 : G = GG_K(1,4);

o6 : ProjectiveVariety, GG(1,4)

i7 : Y := (G * random({{1},{1},{1},{1},{1}},0_G)) % G -- an elliptic curve

o7 = curve in PP^9 cut out by 10 hypersurfaces of degrees 1^5 2^5 

o7 : ProjectiveVariety, curve in PP^9 (subvariety of codimension 5 in G)

i8 : W = Fano Y; -- surface swept out by the lines of Y

o8 : ProjectiveVariety, surface in PP^4

We can recover the subvariety $Y\subset\mathbb{G}(k,\mathbb{P}^n)$ by computing the Fano variety of $k$-planes contained in $W$.

i9 : Fano(1,W) -- variety of lines contained in W

o9 = curve in PP^9 cut out by 10 hypersurfaces of degrees 1^5 2^5 

o9 : ProjectiveVariety, curve in PP^9 (subvariety of codimension 5 in G)

i10 : assert(oo == Y)

Ways to use this method: