MultirationalMap | MultiprojectiveVariety -- restriction of a multi-rational map

Operator: |
Usage:

Phi | Z
Inputs:
- Phi, a multi-rational map, $\Phi:X \dashrightarrow Y$
- Z, a multi-projective variety, a subvariety of $X$
Outputs:
- a multi-rational map, the restriction of $\Phi$ to $Z$, $\phi|_{Z}: Z \dashrightarrow Y$

Description

i1 : ZZ/33331[x_0..x_3], f = rationalMap {x_2^2-x_1*x_3,x_1*x_2-x_0*x_3,x_1^2-x_0*x_2}, g = rationalMap {x_2^2-x_1*x_3,x_1*x_2-x_0*x_3};

i2 : Phi = last graph rationalMap {f,g};

o2 : MultirationalMap (rational map from threefold in PP^3 x PP^2 x PP^1 to PP^2 x PP^1)

i3 : Z = (source Phi) * projectiveVariety ideal random({1,1,2},ring ambient source Phi);

o3 : ProjectiveVariety, surface in PP^3 x PP^2 x PP^1

i4 : Phi' = Phi|Z;

o4 : MultirationalMap (rational map from Z to PP^2 x PP^1)

i5 : source Phi'

o5 = Z

o5 : ProjectiveVariety, surface in PP^3 x PP^2 x PP^1

i6 : assert(image Phi' == Phi Z)

The following is a shortcut to take restrictions on random hypersurfaces as above.

i7 : Phi|{1,1,2};

o7 : MultirationalMap (rational map from surface in PP^3 x PP^2 x PP^1 to PP^2 x PP^1)

MultirationalMap | List
MultirationalMap | MultiprojectiveVariety -- restriction of a multi-rational map
RationalMap | MultiprojectiveVariety

The source of this document is in MultiprojectiveVarieties.m2:3430:0.