dual(SimplicialComplex) -- make the Alexander dual of an abstract simplicial complex

Synopsis

Function: dual
Usage:

dual Delta
Inputs:
- Delta, an abstract simplicial complex,
Outputs:
- an abstract simplicial complex, that is the Alexander dual of $\Delta$

Description

The Alexander dual of an abstract simplicial complex $\Delta$ is the abstract simplicial complex whose faces are the complements of the nonfaces of $\Delta$.

The Alexander dual of a square is the disjoint union of two edges.

i1 : S = ZZ[a..d];

i2 : Δ = simplicialComplex {a*b, b*c, c*d, a*d}

o2 = simplicialComplex | cd ad bc ab |

o2 : SimplicialComplex

i3 : dual Δ

o3 = simplicialComplex | bd ac |

o3 : SimplicialComplex

i4 : assert (dual Δ === simplicialComplex {a*c, b*d})

i5 : assert (dual dual Δ === Δ)

The Alexander dual is homotopy equivalent to the complement of $\Delta$ in the simplex generated by all of the variables in the polynomial ring of $\Delta$. This is known as Alexander Duality. In particular, it depends on the number of variables.

i6 : S' = ZZ[a..e];

i7 : Δ' = simplicialComplex {a*b, b*c, c*d, a*d}

o7 = simplicialComplex | cd ad bc ab |

o7 : SimplicialComplex

i8 : dual Δ'

o8 = simplicialComplex | bde ace abcd |

o8 : SimplicialComplex

i9 : assert (dual Δ' === simplicialComplex {b*d*e, a*c*e, a*b*c*d})

i10 : assert (dual dual Δ' === Δ')

The projective dimension of the Stanley–Reisner ring of $\Delta$ equals the regularity of the Stanley–Reisner ideal of the Alexander dual of $\Delta$; see Theorem 5.59 in Miller-Sturmfels' Combinatorial Commutative Algebra.

i11 : R = QQ[a..h];

i12 : Γ =  bartnetteSphereComplex R

o12 = simplicialComplex | defh befh cdfh bcfh adeh abeh acdh abch defg cefg adfg acfg bdeg bceg abdg abcg bcef acdf abde |

o12 : SimplicialComplex

i13 : dual Γ

o13 = simplicialComplex | aefgh bdfgh abfgh cdegh acegh bcdgh abefh bcdfh acdeh acefg abdfg bcdeg abcdef |

o13 : SimplicialComplex

i14 : pdim comodule ideal Γ

o14 = 4

i15 : regularity ideal dual Γ

o15 = 4

i16 : assert (pdim comodule ideal Γ === regularity ideal dual Γ)

Alexander duality interchanges extremal Betti numbers of the Stanley–Reisner ideals. Following Example 3.2 in Bayer–Charalambous–Popescu's Extremal betti numbers and applications to monomial ideals we have the following.

i17 : R' = QQ[x_0 .. x_6];

i18 : Γ' = simplicialComplex {x_0*x_1*x_3, x_1*x_3*x_4, x_1*x_2*x_4,
          x_2*x_4*x_5, x_2*x_3*x_5, x_3*x_5*x_6, x_3*x_4*x_6,
          x_0*x_4*x_6, x_0*x_4*x_5, x_0*x_1*x_5, x_1*x_5*x_6,
          x_1*x_2*x_6, x_0*x_2*x_6, x_0*x_2*x_3}

o18 = simplicialComplex | x_3x_5x_6 x_1x_5x_6 x_3x_4x_6 x_0x_4x_6 x_1x_2x_6 x_0x_2x_6 x_2x_4x_5 x_0x_4x_5 x_2x_3x_5 x_0x_1x_5 x_1x_3x_4 x_1x_2x_4 x_0x_2x_3 x_0x_1x_3 |

o18 : SimplicialComplex

i19 : I = ideal Γ'

o19 = ideal (x x x , x x x , x x x , x x x , x x x , x x x , x x x , x x x ,
              0 1 2   1 2 3   0 1 4   0 2 4   0 3 4   2 3 4   0 2 5   1 2 5 
      -----------------------------------------------------------------------
      x x x , x x x , x x x , x x x , x x x , x x x , x x x , x x x , x x x ,
       0 3 5   1 3 5   1 4 5   3 4 5   0 1 6   0 3 6   1 3 6   2 3 6   1 4 6 
      -----------------------------------------------------------------------
      x x x , x x x , x x x , x x x )
       2 4 6   0 5 6   2 5 6   4 5 6

o19 : Ideal of R'

i20 : J = ideal dual Γ'

o20 = ideal (x x x x , x x x x , x x x x , x x x x , x x x x , x x x x ,
              0 1 2 4   0 2 3 4   0 1 2 5   1 2 3 5   0 3 4 5   1 3 4 5 
      -----------------------------------------------------------------------
      x x x x , x x x x , x x x x , x x x x , x x x x , x x x x , x x x x ,
       0 1 3 6   1 2 3 6   0 1 4 6   2 3 4 6   0 2 5 6   0 3 5 6   1 4 5 6 
      -----------------------------------------------------------------------
      x x x x )
       2 4 5 6

o20 : Ideal of R'

i21 : betti res I

             0  1  2  3  4 5
o21 = total: 1 21 49 42 15 2
          0: 1  .  .  .  . .
          1: .  .  .  .  . .
          2: . 21 49 42 14 2
          3: .  .  .  .  1 .

o21 : BettiTally

i22 : betti res J

             0  1  2 3 4
o22 = total: 1 14 21 9 1
          0: 1  .  . . .
          1: .  .  . . .
          2: .  .  . . .
          3: . 14 21 7 1
          4: .  .  . 2 .

o22 : BettiTally

Ways to use this method: