Macaulay2 » Documentation
Packages » SimplicialComplexes :: wedge(SimplicialComplex,SimplicialComplex,RingElement,RingElement)
next | previous | forward | backward | up | index | toc

wedge(SimplicialComplex,SimplicialComplex,RingElement,RingElement) -- make the wedge sum of two abstract simplicial complexes



For any two abstract simplicial complexes $\Delta$ and $\Gamma$ with distinguished vertices $u$ and $v$, the wedge sum is the simplicial complex formed by taking the disjoint union of $\Delta$ and $\Gamma$ and then identifying $u$ and $v$.

The bowtie complex is the wedge sum of two 2-simplicies

i1 : S = QQ[a,b,c];
i2 : Δ = simplexComplex(2, S)

o2 = simplicialComplex | abc |

o2 : SimplicialComplex
i3 : R = QQ[d,e,f];
i4 : Γ = simplexComplex(2, R)

o4 = simplicialComplex | def |

o4 : SimplicialComplex
i5 : ΔvΓ = wedge (Δ, Γ, a, f)

o5 = simplicialComplex | ade abc |

o5 : SimplicialComplex
i6 : vertices ΔvΓ

o6 = {a, b, c, d, e}

o6 : List
i7 : assert (# gens ring ΔvΓ === # gens ring Δ + # gens ring Γ - 1)

When the optional argument $\mathrm{Variables}$ is used, the wedge sum is represented by its Stanley–Reisner ideal in a new polynomial ring having this list as variables. The variables in the ring of $\Delta$ corresponds to the first few variables in this new polynomial ring and the variables in the ring of $\Gamma$ correspond to the next few variables in $R$ (omitting the variable corresponding to $v$). This option is particularly convenient when taking the wedge sum of two abstract simplical complexes already defined in the same ring.

i8 : ΔvΓ' = wedge (Δ, Γ, a, d, Variables => toList(x_0..x_4))

o8 = simplicialComplex | x_0x_3x_4 x_0x_1x_2 |

o8 : SimplicialComplex
i9 : vertices ΔvΓ'

o9 = {x , x , x , x , x }
       0   1   2   3   4

o9 : List
i10 : ΔvΓ'' = wedge (Δ, Δ, a, a, Variables => {a,b,c,d,e})

o10 = simplicialComplex | ade abc |

o10 : SimplicialComplex
i11 : vertices ΔvΓ''

o11 = {a, b, c, d, e}

o11 : List
i12 : ring ΔvΓ''

o12 = QQ[a..e]

o12 : PolynomialRing


When the variables in the ring of $\Delta$ and the ring of $\Gamma$ are not disjoint, names of vertices in the wedge sum may not be intelligible; the same name will apparently be used for two distinct variables.

See also

Ways to use this method: