torAlgClass -- the class (w.r.t. multiplication in homology) of a local ring

Synopsis

Usage:

torAlgClass R or torAlgClass I
Inputs:
- R, a quotient ring, of a polynomial algebra by an ideal contained in the irrelevant maximal ideal
Outputs:
- a string, the (parametrized) class of the local ring obtained by localizing R at the irrelevant maximal ideal, provided that this ring is non-zero and of codepth at most 3 or Gorenstein or Golod; otherwise "no class"

Description

Classifies the local ring obtained by localizing R at the irrelevant maximal ideal; it is also possible to call the function on the defining ideal of R; see torAlgClass(Ideal).

If the local ring has codepth at most 3, then it is classified as belonging to one of the (parametrized) classes B, C(c), G(r), H(p,q), S, or T.

i1 : Q = QQ[x,y,z];

i2 : torAlgClass (Q/ideal(x))

o2 = C(0)

i3 : torAlgClass (Q/ideal(x*y))

o3 = C(1)

i4 : torAlgClass (Q/ideal(x^2,y^2))

o4 = C(2)

i5 : torAlgClass (Q/ideal(x^2,y^2,x*y))

o5 = S

i6 : torAlgClass (Q/ideal(x^2,x*y,y*z,z^2))

o6 = B

i7 : torAlgClass (Q/ideal(x^2,y^2,z^2))

o7 = C(3)

i8 : torAlgClass (Q/ideal(x*y,y*z,x^3,x^2*z,x*z^2-y^3,z^3))

o8 = G(3)

i9 : torAlgClass (Q/ideal(x*z+y*z,x*y+y*z,x^2-y*z,y*z^2+z^3,y^3-z^3))

o9 = G(5), Gorenstein

i10 : torAlgClass (Q/ideal(x^2,y^2,z^2,x*y))

o10 = H(3,2)

i11 : torAlgClass (Q/ideal(x^2,y^2,z^2,x*y*z))

o11 = T

If the local ring is Gorenstein or Golod of codepth 4, then it is classified as belonging to one of the (parametrized) classes C(4), GH(p), GS, GT, or codepth 4 Golod.

i12 : Q = QQ[w,x,y,z];

i13 : torAlgClass (Q/ideal(w^2,x^2,y^2,z^2))

o13 = C(4)

i14 : torAlgClass (Q/ideal(y*z,x*z,x*y+z^2,x^2,w*x+y^2+z^2,w^2+w*y+y^2+z^2))

o14 = GH(5)

i15 : torAlgClass (Q/ideal(z^2,x*z,w*z+y*z,y^2,x*y,w*y,x^2,w*x+y*z,w^2+y*z))

o15 = GS

i16 : torAlgClass (Q/ideal(x^2,y^2,z^2,x*w,y*w,z*w,w^3-x*y*z))

o16 = GT

i17 : torAlgClass (Q/(ideal(w,x,y,z))^2)

o17 = codepth 4 Golod

If the local ring has codepth at least 5, then it is classified as belonging to one of the classes C(c), if it is complete intersection, codepth c Gorenstein, if it is Gorenstein and not complete intersection, codepth c Golod, if it is Golod, and no class otherwise.

i18 : Q = QQ[u,v,w,x,y,z];

i19 : torAlgClass (Q/ideal(u^2,v^2,w^2,x^2+y^2, x^2+z^2))

o19 = C(5)

i20 : torAlgClass (Q/ideal(w^2,v*w,z*w,y*w,v^2,z*v+x*w,y*v,x*v,z^2+x*w,y*z,x*z,y^2+x*w,x*y,x^2))

o20 = codepth 5 Gorenstein

i21 : torAlgClass (Q/ideal(x^2*y^2,x^2*z,y^2*z,u^2*z,v^2*z,w^2*z))

o21 = codepth 5 Golod

i22 : torAlgClass (Q/ideal(u^2,v^2,w^2,x^2,z^2,x*y^15))

o22 = codepth 6 no class

If the defining ideal of R is not contained in the irrelevant maximal ideal, then the resulting local ring is zero, and the function returns zero ring.

i23 : Q = QQ[x,y,z];

i24 : torAlgClass (Q/ideal(x^2-1))

o24 = zero ring

Ways to use torAlgClass:

torAlgClass(QuotientRing)
torAlgClass(Ideal) -- the class (w.r.t. multiplication in homology) of a local ring

For the programmer

The object torAlgClass is a method function.