Macaulay2 » Documentation
Packages » GradedLieAlgebras :: First Lie algebra tutorial
next | previous | forward | backward | up | index | toc

First Lie algebra tutorial

In this elementary tutorial, we give a brief introduction on how to use the package GradedLieAlgebras.

The most common way to construct a Lie algebra is by means of the constructor lieAlgebra, which produces a free Lie algebra on the generators given in input.

i1 : L = lieAlgebra{a,b}

o1 = L

o1 : LieAlgebra
i2 : dims(1,5,L)

o2 = {2, 1, 2, 3, 6}

o2 : List

The above list is the dimensions in degrees 1 to 5 of the free Lie algebra on two generators (of degree 1). To get an explicit basis in a certain degree, use basis(ZZ,LieAlgebra).

i3 : basis(2,L)

o3 = {(b a)}

o3 : List
i4 : basis(3,L)

o4 = {(a b a), (b b a)}

o4 : List

The basis elements in degree 3 given above should be interpreted as [$a$, [$b$, $a$ ]] and [$b$, [$b$, $a$]]. To multiply two Lie elements, use LieElement LieElement. The operator SPACE is right associative, so writing ($a$ $a$ $a$ $b$) as input gives the Lie monomial [$a$, [$a$, [$a$, $b$]]], which in output is written in the same way as input. A linear combination of Lie monomials is written in the natural way.

i5 : p = (a b) (a a b + 3 b b a)

o5 =  - (a b a b a) + 3 (a b b b a) + (b a a b a) - 3 (b b a b a)

o5 : L

The output is a linear combination of the basis elements of degree 5.

i6 : basis(5,L)

o6 = {(a a a b a), (b a a b a), (a b a b a), (b b a b a), (a b b b a), (b b b
     b a)}

o6 : List

The element $p$ in $L$ may be used to define a quotient Lie algebra by the ideal generated by $p$.

i7 : Q = L/{p}

o7 = Q

o7 : LieAlgebra
i8 : dims(1,5,Q)

o8 = {2, 1, 2, 3, 5}

o8 : List

As expected, the dimension in degree 5 of $Q$ is 1 less than that of $L$.

When $L$ is a big free Lie algebra it may be better to define the relations in a "formal" manner. For an example, see Minimal models, Ext-algebras and Koszul duals.

A generator for a Lie algebra may be any variable name including indexed variables. Also, the same names can be used in different Lie algebras or even rings. Use use(LieAlgebra) to switch between Lie algebras.

i9 : L = lieAlgebra{a,b}

o9 = L

o9 : LieAlgebra
i10 : M = lieAlgebra{a,b}/{a b}

o10 = M

o10 : LieAlgebra
i11 : R = QQ[a,b]

o11 = R

o11 : PolynomialRing
i12 : use L
i13 : a b

o13 =  - (b a)

o13 : L
i14 : use M
i15 : a b

o15 = 0

o15 : M
i16 : use R

o16 = R

o16 : PolynomialRing
i17 : a*b

o17 = a*b

o17 : R

See also