eulerRestriction(CentralArrangement,List,ZZ) -- form the Euler restriction of a central multiarrangement

Synopsis

Function: eulerRestriction
Usage:

eulerRestriction(A, m, i)
Inputs:
- A, a central hyperplane arrangement,
- m, a list,
- i, an integer,
Outputs:
- a sequence, the Euler restriction of (A,m)

Description

The Euler restriction of a multiarrangement (introduced by Abe, Terao, and Wakefield in The Euler multiplicity and addition–deletion theorems for multiarrangements, J. Lond. Math. Soc. (2) 77 (2008), no. 2, 335348.) generalizes restriction to multiarrangements in such a way that addition-deletion theorems hold. The underlying simple arrangement of the Euler restriction is simply the usual restriction; however, the multiplicities are generally smaller than the naive ones.

If all of the multiplicities are $1$, the same is true of the Euler restriction:

i1 : R = QQ[x,y,z]

o1 = R

o1 : PolynomialRing

i2 : A = arrangement {x,y,z,x-y,x-z}

o2 = {x, y, z, x - y, x - z}

o2 : Hyperplane Arrangement

i3 : (A'',m'') = eulerRestriction(A,{1,1,1,1,1},1)

o3 = ({z, x, x - z}, {1, 1, 1})

o3 : Sequence

i4 : restriction(A,1)

o4 = {x, z, x, x - z}

o4 : Hyperplane Arrangement

i5 : trim oo -- same underlying simple arrangement, different multiplicities

o5 = {x - z, z, x}

o5 : Hyperplane Arrangement

If $({\mathcal A},m)$ is a free multiarrangement and so is $({\mathcal A},m')$, where $m'$ is obtained from $m$ by lowering a single multiplicity by one, the Euler restriction is free as well, and the modules of logarithmic derivations form a short exact sequence. See the paper of Abe, Terao and Wakefield for details.

i6 : m = {2,2,2,2,1}; m' = {2,2,2,1,1};

i8 : (A'',m'') = eulerRestriction(A,m,3)

o8 = ({y - z, z, y}, {1, 2, 3})

o8 : Sequence

i9 : prune image der(A,m)

      3
o9 = R

o9 : R-module, free, degrees {3:3}

i10 : prune image der(A,m')

       3
o10 = R

o10 : R-module, free, degrees {2..3, 3}

i11 : prune image der(A'',m'')

                2
o11 = (QQ[y..z])

o11 : QQ[y..z]-module, free, degrees {2:3}

It may be the case that the Euler restriction is free, while the naive restriction is not:

i12 : A = arrangement "bracelet";

i13 : (B,m) = eulerRestriction(A,{1,1,1,1,1,1,1,1,1},0)

o13 = ({x  + x , x , x , x  + x  + x , x  + x , x }, {1, 1, 1, 1, 1, 1})
         3    4   3   4   2    3    4   2    4   2

o13 : Sequence

i14 : C = restriction(A,0)

o14 = {x , x , x , x  + x , x  + x , x  + x , x  + x , x  + x  + x }
        2   3   4   2    4   3    4   2    4   3    4   2    3    4

o14 : Hyperplane Arrangement

i15 : assert(isFreeModule prune image der B) -- one is free

i16 : assert(not isFreeModule prune image der C) -- the other is not

Ways to use this method: