flagfVector(List,SimplicialComplex) -- compute a flag $f$-number of a colored simplicial complex

Synopsis

Function: flagfVector
Usage:

f = flagfVector(L, Delta)
Inputs:
- L, a list,
- Delta, an abstract simplicial complex,
Outputs:
- an integer, the flag f-number corresponding to the color set determined by L

Description

A coloring of an abstract simplicial complex $\Delta$ is a labelling of its vertices with colors. The color set of a face is the set of colors of its vertices. Given a set of colors $L$, the flag $f$-number $f_L(\Delta)$ is the number of faces with color set $L$. In this package, a coloring of an abstract simplicial complex is determined by a multigrading of its ambient ring.

If we color the $2$-simplex with distinct colors, each color set corresponds to a unique face.

i1 : S = QQ[a,b,c, DegreeRank => 3];

i2 : degrees S

o2 = {{1, 0, 0}, {0, 1, 0}, {0, 0, 1}}

o2 : List

i3 : Δ = simplexComplex(2, S)

o3 = simplicialComplex | abc |

o3 : SimplicialComplex

i4 : flagfVector({0,0,0}, Δ)

o4 = 1

i5 : flagfVector({1,0,0}, Δ)

o5 = 1

i6 : flagfVector({0,1,0}, Δ)

o6 = 1

i7 : flagfVector({0,0,1}, Δ)

o7 = 1

i8 : flagfVector({0,1,1}, Δ)

o8 = 1

i9 : flagfVector({1,0,1}, Δ)

o9 = 1

i10 : flagfVector({1,1,0}, Δ)

o10 = 1

i11 : flagfVector({1,1,1}, Δ)

o11 = 1

A coloring is proper if no two vertices in the same face have the same color. The bowtie complex has a proper $3$-coloring.

i12 : R = ZZ[a..e, Degrees => {{1,0,0},{0,1,0},{0,0,1},{1,0,0},{0,1,0}}];

i13 : Γ = simplicialComplex {a*b*c, c*d*e}

o13 = simplicialComplex | cde abc |

o13 : SimplicialComplex

i14 : assert isProper Γ

i15 : flagfVector({0,0,0}, Γ)

o15 = 1

i16 : flagfVector({1,0,0}, Γ)

o16 = 2

i17 : flagfVector({0,1,0}, Γ)

o17 = 2

i18 : flagfVector({0,0,1}, Γ)

o18 = 1

i19 : flagfVector({0,1,1}, Γ)

o19 = 2

i20 : flagfVector({1,0,1}, Γ)

o20 = 2

i21 : flagfVector({1,1,0}, Γ)

o21 = 2

i22 : flagfVector({1,1,1}, Γ)

o22 = 2

The method function $\operatorname{flagfVector}$ does not check whether the multigrading on ambient ring determines a proper coloring.

The flag $f$-vector is computed as the multigraded Hilbert function of the quotient of an exterior algebra by the corresponding Stanley–Reisner ideal.

Caveat

Not every grading of the ambient polynomial ring corresponds to a coloring.

Ways to use this method: