Macaulay2 » Documentation
Packages » SimplicialComplexes :: isPure(SimplicialComplex)
next | previous | forward | backward | up | index | toc

isPure(SimplicialComplex) -- whether the facets are equidimensional



An abstract simplicial complex is pure of dimension $d$ if every facet has the same dimension.

Many classic examples of abstract simplicial complexes are pure.

i1 : S = ZZ[x_1..x_18];
i2 : isPure simplexComplex(5, S)

o2 = true
i3 : isPure bartnetteSphereComplex S

o3 = true
i4 : isPure bjornerComplex S

o4 = true
i5 : isPure dunceHatComplex S

o5 = true
i6 : isPure poincareSphereComplex S

o6 = true

The abstract simplicial complex from Example 1.8 of Miller-Sturmfels' Combinatorial Commutative Algebra consists of a triangle (on vertices $a$, $b$, $c$), two edges (connecting $c$ to $d$ and $b$ to $d$), and an isolated vertex (namely $e$). It has six minimal nonfaces. Moreover, its 1-skeleton and 2-skeleton are not pure.

i7 : R = ZZ/101[a..f];
i8 : Γ = simplicialComplex {e, c*d, b*d, a*b*c}

o8 = simplicialComplex | e cd bd abc |

o8 : SimplicialComplex
i9 : isPure Γ

o9 = false
i10 : isPure skeleton (1, Γ)

o10 = false
i11 : isPure skeleton (2, Γ)

o11 = false

There are two "trivial" simplicial complexes: the irrelevant complex has the empty set as a facet whereas the void complex has no faces. Both are pure.

i12 : irrelevant = simplicialComplex monomialIdeal gens S

o12 = simplicialComplex | 1 |

o12 : SimplicialComplex
i13 : isPure irrelevant

o13 = true
i14 : void = simplicialComplex monomialIdeal 1_S

o14 = simplicialComplex 0

o14 : SimplicialComplex
i15 : isPure void

o15 = true

See also

Ways to use this method: