Macaulay2 » Documentation
Packages » SimplicialComplexes :: skeleton(ZZ,SimplicialComplex)
next | previous | forward | backward | up | index | toc

skeleton(ZZ,SimplicialComplex) -- make a new simplicial complex generated by all faces of a bounded dimension

Description

The $k$-skeleton of an abstract simplicial complex is the subcomplex consisting of all of the faces of dimension at most $k$. When the abstract simplicial complex is pure its $k$-skeleton is simply generated by its $k$-dimensional faces.

The boundary of the 4-simplex is a simplicial 3-sphere with 5 vertices, 5 facets, and a minimal nonface that corresponds to the interior of the sphere.

i1 : S = ZZ[a..e];
 
i2 : Δ = simplicialComplex monomialIdeal (a*b*c*d*e)

o2 = simplicialComplex | bcde acde abde abce abcd |

o2 : SimplicialComplex
 
i3 : skeleton (-2, Δ)

o3 = simplicialComplex 0

o3 : SimplicialComplex
 
i4 : assert (skeleton (-2, Δ) === simplicialComplex monomialIdeal 1_S)
 
i5 : skeleton (-1, Δ)

o5 = simplicialComplex | 1 |

o5 : SimplicialComplex
 
i6 : assert (skeleton (-1, Δ) === simplicialComplex {1_S})
 
i7 : skeleton (0, Δ)

o7 = simplicialComplex | e d c b a |

o7 : SimplicialComplex
 
i8 : assert (skeleton (0, Δ) === simplicialComplex gens S)
 
i9 : skeleton (1, Δ)

o9 = simplicialComplex | de ce be ae cd bd ad bc ac ab |

o9 : SimplicialComplex
 
i10 : assert (skeleton (1, Δ) === simplicialComplex apply (subsets (gens S, 2), product))
 
i11 : skeleton (2, Δ)

o11 = simplicialComplex | cde bde ade bce ace abe bcd acd abd abc |

o11 : SimplicialComplex
 
i12 : assert (skeleton (2, Δ) === simplicialComplex apply (subsets (gens S, 3), product))
 
i13 : skeleton (3, Δ)

o13 = simplicialComplex | bcde acde abde abce abcd |

o13 : SimplicialComplex
 
i14 : assert (skeleton (3, Δ) === Δ)
 
i15 : fVector Δ

o15 = {1, 5, 10, 10, 5}

o15 : List

The abstract simplicial complex from Example 1.8 of Miller-Sturmfels' Combinatorial Commutative Algebra consists of a triangle (on vertices $a$, $b$, $c$), two edges (connecting $c$ to $d$ and $b$ to $d$), and an isolated vertex (namely $e$). It has six minimal nonfaces. Moreover, its 1-skeleton and 2-skeleton are not pure.

i16 : R = ZZ/101[a..f];
 
i17 : Γ = simplicialComplex {e, c*d, b*d, a*b*c}

o17 = simplicialComplex | e cd bd abc |

o17 : SimplicialComplex
 
i18 : skeleton (-7, Γ)

o18 = simplicialComplex 0

o18 : SimplicialComplex
 
i19 : assert (skeleton (-7, Γ) === simplicialComplex monomialIdeal 1_R)
 
i20 : skeleton (-1, Γ)

o20 = simplicialComplex | 1 |

o20 : SimplicialComplex
 
i21 : assert (skeleton (-1, Γ) === simplicialComplex {1_R})
 
i22 : skeleton (0, Γ)

o22 = simplicialComplex | e d c b a |

o22 : SimplicialComplex
 
i23 : assert (skeleton (0, Γ) === simplicialComplex {a, b, c, d, e})
 
i24 : skeleton (1, Γ)

o24 = simplicialComplex | e cd bd bc ac ab |

o24 : SimplicialComplex
 
i25 : assert (skeleton (1, Γ) === simplicialComplex {e, c*d, b*d, b*c, a*c, a*b})
 
i26 : skeleton (2, Γ)

o26 = simplicialComplex | e cd bd abc |

o26 : SimplicialComplex
 
i27 : assert (skeleton (2, Γ) === Γ)

See also

Ways to use this method:

The source of this document is in SimplicialComplexes/Documentation.m2:1900:0.