matrix(SimplicialMap) -- get the underlying map of rings

Synopsis

Function: matrix
Usage:

g = matrix f
Inputs:
- f, a map of abstract simplicial complexes,
Optional inputs:
- Degree => ..., default value null, unused
Outputs:
- g, a matrix, having one row

Description

A simplicial map is a map $f \colon \Delta \to \Gamma$ such that for any face $F \subset \Delta$, the image $f(F)$ is contained in a face of $\Gamma$. Since an abstract simplicial complex is, in this package, represented by its Stanley–Reisner ideal in a polynomial ring, the simplicial map $f$ corresponds to a ring map from the ring of $\Delta$ to the ring of $\Gamma$. The ring map is described by a matrix having one row; the entry in the $i$-th column is the image in the ring of $\Gamma$ of the $i$-th variable in the ring $\Delta$. This method returns this matrix.

For the identity map, the matrix of variables in the ambient polynomial ring.

i1 : S = ZZ[x_0..x_5];

i2 : Δ = simplicialComplex monomialIdeal(x_0*x_5, x_1*x_4, x_2*x_3)

o2 = simplicialComplex | x_3x_4x_5 x_2x_4x_5 x_1x_3x_5 x_1x_2x_5 x_0x_3x_4 x_0x_2x_4 x_0x_1x_3 x_0x_1x_2 |

o2 : SimplicialComplex

i3 : id_Δ

o3 = | x_0 x_1 x_2 x_3 x_4 x_5 |

o3 : SimplicialMap simplicialComplex | x_3x_4x_5 x_2x_4x_5 x_1x_3x_5 x_1x_2x_5 x_0x_3x_4 x_0x_2x_4 x_0x_1x_3 x_0x_1x_2 | <--- simplicialComplex | x_3x_4x_5 x_2x_4x_5 x_1x_3x_5 x_1x_2x_5 x_0x_3x_4 x_0x_2x_4 x_0x_1x_3 x_0x_1x_2 |

i4 : matrix id_Δ

o4 = | x_0 x_1 x_2 x_3 x_4 x_5 |

             1      6
o4 : Matrix S  <-- S

i5 : assert(matrix id_Δ === vars S)

The next map projects an octahedron onto a square.

i6 : R = ZZ[y_0..y_3];

i7 : Γ = simplicialComplex monomialIdeal(y_1*y_2)

o7 = simplicialComplex | y_0y_2y_3 y_0y_1y_3 |

o7 : SimplicialComplex

i8 : f = map(Γ, Δ, {y_0,y_0,y_1,y_2,y_3,y_3})

o8 = | y_0 y_0 y_1 y_2 y_3 y_3 |

o8 : SimplicialMap simplicialComplex | y_0y_2y_3 y_0y_1y_3 | <--- simplicialComplex | x_3x_4x_5 x_2x_4x_5 x_1x_3x_5 x_1x_2x_5 x_0x_3x_4 x_0x_2x_4 x_0x_1x_3 x_0x_1x_2 |

i9 : matrix f

o9 = | y_0 y_0 y_1 y_2 y_3 y_3 |

             1      6
o9 : Matrix R  <-- R

This matrix is simply extracted from the underlying map of rings.

i10 : code(matrix, SimplicialMap)

o10 = -- code for method: matrix(SimplicialMap)
      /usr/local/share/Macaulay2/
      SimplicialComplexes/Code.m2:901:34-901:59: --source code:
      matrix SimplicialMap := Matrix => opts -> f -> matrix map f

Ways to use this method: