VirtualResolutions -- a package for computing virtual resolutions

While graded minimal free resolutions are useful for studying quasicoherent sheaves over projective space, when working over a product of projective spaces or, more generally, over smooth projective toric varieties, graded minimal free resolutions over the Cox ring seem too restricted by algebraic structure that is in some sense unimportant geometrically. By allowing a limited amount of homology, virtual resolutions offer a more flexible alternative for studying toric subvarieties when compared to minimal graded free resolutions.

Introduced by Berkesch, Erman, and Smith in Virtual resolutions for a product of projective spaces (see [BES20, arXiv:1703.07631]) if $X$ is a smooth toric variety, $S$ is the Cox ring of $X$ graded by the Picard group of $X$, and $B\subset S$ is the irrelevant ideal of $X$, then a virtual resolution of a graded $S$-module $M$ is a complex of graded free $S$-modules, which sheafifies to a resolution of the associated sheaf of $M$.

This package provides tools for constructing and studying virtual resolutions for products of projective spaces. In particular, it implements a number of the methods for constructing virtual resolutions for products of projective spaces as introduced by Berkesch, Erman, and Smith. This package also contains methods for constructing curves in $\PP^1\times\PP^2$, as these are a natural source for interesting virtual resolutions.

As a running example, consider three points $([1:1],[1:4])$, $([1:2],[1:5])$, and $([1:3],[1:6])$ in $\PP^1 \times \PP^1$.

i1 : X = toricProjectiveSpace(1)**toricProjectiveSpace(1);

i2 : S = ring X;

i3 : B = ideal X;

o3 : Ideal of S

i4 : J = saturate(intersect(
         ideal(x_1 - x_0, x_3 - 4*x_2),
         ideal(x_1 - 2*x_0, x_3 - 5*x_2),
         ideal(x_1 - 3*x_0, x_3 - 6*x_2)), B);

o4 : Ideal of S

i5 : minres = res J;

i6 : multigraded betti minres

        0                   1                         2               3
o6 = 0: 1                   .                         .               .
     2: .                 a*b                         .               .
     3: . a^3+a^2*b+a*b^2+b^3                         .               .
     4: .                   . 2*a^3*b+2*a^2*b^2+2*a*b^3               .
     5: .                   .                         . a^3*b^2+a^2*b^3

o6 : MultigradedBettiTally

As described in Algorithm 3.4 of Berkesch, Erman, and Smith's paper, one may construct a virtual resolution of a module from its graded minimal free resolution and an element of the multigraded Castelnuovo-Mumford regularity of the module. (See Maclagan and Smith's paper Multigraded Castelnuovo-Mumford Regularity (see [MS04, arXiv:math/0305214]) for the definition of multigraded regularity.) Building on the TateOnProducts and LinearTruncations packages, this package contains a function allowing one to compute the minimal elements of the multigraded Castelnuovo-Mumford regularity of a $B$-saturated module.

Continuing the example from above, we see that $(2,0)$ is an element of the multigraded regularity of $S/J$. From this we can compute a virtual resolution of $S/J$.

i7 : multigradedRegularity(X, J)

o7 = {{0, 2}, {1, 1}, {2, 0}}

o7 : List

i8 : vres = virtualOfPair(J, {{3,1}})

      1      3      2
o8 = S  <-- S  <-- S  <-- 0 <-- 0
                                 
     0      1      2      3     4

o8 : ChainComplex

i9 : multigraded betti vres

        0         1       2
o9 = 0: 1         .       .
     2: .       a*b       .
     3: . a^3+a^2*b       .
     4: .         . 2*a^3*b

o9 : MultigradedBettiTally

Notice that this virtual resolution of $S/J$ is much shorter and thinner than the graded minimal free resolution of $S/J$. This is a common theme: virtual resolutions tend to be much shorter and less wide than graded minimal free resolutions over the Cox ring, but they still preserve geometric information about $S/J$.

In addition to the functions highlighted above, the VirtualResolutions package contains a number of other tools for constructing and studying virtual resolutions. In particular, there are functions to construct virtual resolutions for zero dimensional subschemes, to check whether a complex is a virtual resolution, and to construct curves in $\PP^1\times\PP^2$.

The following people have generously contributed code or worked on this package.

• Daniel Erman
• Gregory G. Smith
• Lauren Cranton Heller

• [BES20]: Berkesch, Erman, and Smith, Virtual resolutions for a product of projective spaces (see arXiv:1703.07631).
• [MS04]: Maclagan and Smith, Multigraded Castelnuovo-Mumford Regularity (see arXiv:math/0305214).

Authors

• Ayah Almousa <[email protected]>
• Christine Berkesch <[email protected]>
• Juliette Bruce <[email protected]>
• David Eisenbud <[email protected]>
• Michael Loper <[email protected]>
• Mahrud Sayrafi <[email protected]>

Certification

Version 1.2 of this package was accepted for publication in volume 10 of The Journal of Software for Algebra and Geometry on 19 May 2020, in the article The virtual resolutions package for Macaulay2 (DOI: 10.2140/jsag.2020.10.51). That version can be obtained from the journal or from the Macaulay2 source code repository.

Version

This documentation describes version 1.4 of VirtualResolutions.

Source code

The source code from which this documentation is derived is in the file VirtualResolutions.m2. The auxiliary files accompanying it are in the directory VirtualResolutions/.

Exports