Macaulay2 » Documentation
Packages » HyperplaneArrangements :: subArrangement(Arrangement,Flat)
next | previous | forward | backward | up | index | toc

subArrangement(Arrangement,Flat) -- create the hyperplane arrangement containing a flat

Description

For any hyperplane arrangement $A$ and any flat $F$ in $A$, this methods creates a new hyperplane arrangement formed by the hyperplanes in $A$ that contain the linear subspace associated to the flat $A$.

We illustrate this method with the Coxeter arrangement of type A.

i1 : S = QQ[w, x, y, z];
 
i2 : A3 = typeA(3, S)

o2 = {w - x, w - y, w - z, x - y, x - z, y - z}

o2 : Hyperplane Arrangement 
i3 : F1 = flat(A3, {3,4,5})

o3 = {3, 4, 5}

o3 : Flat of {w - x, w - y, w - z, x - y, x - z, y - z}
 
i4 : A3' = subArrangement(A3, F1)

o4 = {x - y, x - z, y - z}

o4 : Hyperplane Arrangement 
i5 : assert(ring A3 === ring A3')
 
i6 : subArrangement flat(A3, {0, 5})

o6 = {w - x, y - z}

o6 : Hyperplane Arrangement 
i7 : F2 = flat(A3, {0, 1, 3})

o7 = {0, 1, 3}

o7 : Flat of {w - x, w - y, w - z, x - y, x - z, y - z}
 
i8 : assert(typeA(2, S) == A3_F2)
 
i9 : assert(A3 === subArrangement flat(A3, {0,1,2,3,4,5}))

An extension of the bracelet arrangement has several subarrangements isomorphic to $A_3$.

i10 : B = arrangement("bracelet", S);
 
i11 : B' = arrangement({w+x+y+z} | hyperplanes B)

o11 = {w + x + y + z, w, x, y, w + z, x + z, y + z, w + x + z, w + y + z, x + y + z}

o11 : Hyperplane Arrangement 
i12 : subArrangement flat(B', {0,1,2,6,8,9})

o12 = {w + x + y + z, w, x, y + z, w + y + z, x + y + z}

o12 : Hyperplane Arrangement 
i13 : subArrangement flat(B', {0,1,3,5,7,9})

o13 = {w + x + y + z, w, y, x + z, w + x + z, x + y + z}

o13 : Hyperplane Arrangement 
i14 : subArrangement flat(B', {0,2,3,4,7,8})

o14 = {w + x + y + z, x, y, w + z, w + x + z, w + y + z}

o14 : Hyperplane Arrangement

See also

Ways to use this method:

The source of this document is in HyperplaneArrangements.m2:3054:0.