NumericalAlgebraicGeometry -- Numerical Algebraic Geometry

Description

i1 : R = CC[x,y,z];

i2 : F = {x^2+y^2+z^2-1, y-x^2, z-x^3};

i3 : s = solveSystem F 

o3 = {{.540536+1.03152*ii, -.771845+1.11514*ii, -1.5675-.193395*ii},
     ------------------------------------------------------------------------
     {-.737353, .543689, -.400891}, {-.540536-1.03152*ii,
     ------------------------------------------------------------------------
     -.771845+1.11514*ii, 1.5675+.193395*ii}, {-.540536+1.03152*ii,
     ------------------------------------------------------------------------
     -.771845-1.11514*ii, 1.5675-.193395*ii}, {.737353, .543689, .400891},
     ------------------------------------------------------------------------
     {.540536-1.03152*ii, -.771845-1.11514*ii, -1.5675+.193395*ii}}

o3 : List

i4 : realPoints s

o4 = {{-.737353, .543689, -.400891}, {.737353, .543689, .400891}}

o4 : List

i5 : R = CC[x,y,z];

i6 : sph = x^2+y^2+z^2-1; 

i7 : I = ideal {x*sph*(y-x^2), sph*(z-x^3)};

o7 : Ideal of R

i8 : numericalIrreducibleDecomposition I 

o8 = a "numerical variety" with components in
     dim 1:  (dim=1,deg=1) (dim=1,deg=3)
     dim 2:  (dim=2,deg=2)

o8 : NumericalVariety

Basic types (such as Point and WitnessSet) are defined in the package NAGtypes.

Basic functions:

• track -- track a linear segment homotopy given start and target system
• solveSystem -- solve a system of polynomial equations
• refine -- refine numerical solutions to a system of polynomial equations
• totalDegreeStartSystem -- construct a start system for the total degree homotopy
• numericalIrreducibleDecomposition -- constructs a numerical variety defined by the given ideal
• sample -- sample a point on a component
• isSubset(NumericalVariety,NumericalVariety)

Service functions:

• Many service functions (such as areEqual and sortSolutions) are defined in the package NAGtypes.
• setDefault -- set/get the default parameters for continuation algorithms
• getDefault -- set/get the default parameters for continuation algorithms
• NAGtrace -- set the trace level in NumericalAlgebraicGeometry package
• newton -- Newton-Raphson method
• isOn -- determines if a point belongs to a variety
• union -- compute the union
• removeRedundantComponents -- remove redundant components

Functions related to Certified tracking:

• randomInitialPair -- a random initial pair
• goodInitialPair -- make an initial pair conjectured to be good by Shub and Smale
• randomSd -- a random homogeneous system of polynomial equations

References:

• A.J. Sommese, J. Verschelde, and C.W. Wampler, "Introduction to numerical algebraic geometry", in "Solving polynomial equations" (2005), 301--338
• A.J. Sommese and C.W. Wampler, "The numerical solution of systems of polynomials", World Scientific Publishing (2005)
• C. Beltran and A. Leykin, "Certified numerical homotopy tracking", Experimental Mathematics 21(1): 69-83 (2012)
• R. Krone and A. Leykin, "Numerical algorithms for detecting embedded components.", arXiv:1405.7871