map(FlagBundle,AbstractVariety,AbstractSheaf) -- maps to projective bundles

Synopsis

Function: map
Usage:

map(P,X,L)
Inputs:
- P, an abstract flag bundle, the projectivization of some vector bundle E
- X, an abstract variety,
- L, an abstract sheaf, a line bundle on X, the desired pullback of $O_P(1)$.
Optional inputs:
- Degree => ..., default value null,
- DegreeLift => ..., default value null,
- DegreeMap => ..., default value null,
Outputs:
- an abstract variety map, the map from X to P such that the pullback of $O_P(1)$ is $L$

Description

Accepts both Grothendieck-style and Fulton-style ${\mathbb P}(E)$, but in the case a decision cannot be made based on ranks (i.e. when $E$ has rank $2$), defaults to Fulton-style notation (so ${\mathbb P}(E)$ is the space of sub-line-bundles of $E$).

Does not check whether $L$ is basepoint-free. Weird results are probably possible if $L$ is not.

i1 : X = flagBundle({2,2}) --the Grassmannian GG(1,3)

o1 = X

o1 : a flag bundle with subquotient ranks {2:2}

i2 : (S,Q) = bundles X

o2 = (S, Q)

o2 : Sequence

i3 : L = exteriorPower(2,dual S)

o3 = L

o3 : an abstract sheaf of rank 1 on X

i4 : P = flagBundle({5,1}) --Grothendieck-style PP^5

o4 = P

o4 : a flag bundle with subquotient ranks {5, 1}

i5 : f = map(P,X,L) -- Plücker embedding of GG(1,3) in PP^5

o5 = f

o5 : a map to P from X

i6 : H = last bundles P

o6 = H

o6 : an abstract sheaf of rank 1 on P

i7 : f^* (chern(1,H)) -- hyperplane section, should be sigma_1

o7 = H
      2,1

                                   QQ[][H   ..H   ]
                                         1,1   2,2
o7 : ---------------------------------------------------------------------------
     (- H    - H   , - H    - H   H    - H   , - H   H    - H   H   , -H   H   )
         1,1    2,1     1,2    1,1 2,1    2,2     1,2 2,1    1,1 2,2    1,2 2,2

i8 : f_* chern(0,S) --expect 2 times hyperplane class since GG(1,3) has degree 2

o8 = 2H
       2,1

                                             QQ[][H   ..H   , H   ]
                                                   1,1   1,5   2,1
o8 : ------------------------------------------------------------------------------------------------------
     (- H    - H   , - H    - H   H   , - H    - H   H   , - H    - H   H   , - H    - H   H   , -H   H   )
         1,1    2,1     1,2    1,1 2,1     1,3    1,2 2,1     1,4    1,3 2,1     1,5    1,4 2,1    1,5 2,1

Ways to use this method: