AbstractVariety -- the class of all abstract varieties

Description

An abstract variety in Schubert2 is defined by its dimension and by a $\QQ$-algebra $A$, interpreted as the intersection ring. For example, the following code defines the abstract variety corresponding to $\PP^2$.

i1 : A=QQ[t]/ideal(t^3)

o1 = A

o1 : QuotientRing

i2 : X=abstractVariety(2,A)

o2 = X

o2 : an abstract variety of dimension 2

Once the variety $X$ is created, we can access its structure sheaf $O_X$ via the operator OO, and view its Chern class:

i3 : OO_X

o3 = a sheaf

o3 : an abstract sheaf of rank 1 on X

i4 : chern OO_X

o4 = 1

o4 : A

A variable of type AbstractVariety is implemented as a mutable hash table, and can contain other information, such as the variety's tangent bundle, stored under the key TangentBundle. Installation of a variety's tangent bundle enables the computation of its Todd class.

i5 : X.TangentBundle  = abstractSheaf(X,Rank=>2, ChernClass=>(1+t)^3)

o5 = a sheaf

o5 : an abstract sheaf of rank 2 on X

i6 : todd X

         3     2
o6 = 1 + -t + t
         2

o6 : A

To enable the computation of such things as the Euler characteristic of a sheaf, we must also specify a method to take the integral of an element of the intersection ring $A$; in the case where $A$ is Gorenstein, as is the case for the intersection ring modulo numerical equivalence of a complete nonsingular variety, the integral can often be implemented as the functional that takes the coefficient of the highest degree component with respect to a suitable basis of monomials. The default integration method installed by such functions as base and abstractVariety for varieties of dimension greater than 0 returns a symbolic expression indicating the further integration that ought to be done. In this example, we choose to implement the integral by taking the coefficient of the monomial in our ring of top degree.

i7 : integral A := f -> coefficient(t^2,f);

Now we can compute the Euler characteristic of the line bundle whose first Chern class is $2t$ (the algorithm uses the Todd class and the Riemann-Roch formula):

i8 : chi OO_X(2*t)

o8 = 6

o8 : QQ

There are several other methods for constructing abstract varieties: the following functions construct basic useful varieties: abstractProjectiveSpace, projectiveBundle, flagBundle, and base.

Types of abstract variety:

FlagBundle -- the class of all flag bundles

Functions and methods returning an abstract variety:

abstractVariety -- see abstractVariety(ZZ,Ring) -- make an abstract variety
base -- make an abstract variety from nothing, equipped with some parameters and some bundles
degeneracyLocus -- see degeneracyLocus(ZZ,AbstractSheaf,AbstractSheaf)
intermediates(IncidenceCorrespondence) -- see intermediates
kernelBundle -- see kernelBundle(ZZ,AbstractSheaf,AbstractSheaf)
sectionZeroLocus -- see sectionZeroLocus(AbstractSheaf)
source(AbstractVarietyMap) -- the source of a map of abstract varieties
source(Correspondence) -- the source of a correspondence
target(AbstractVarietyMap) -- the target of a map of abstract varieties
target(Correspondence) -- the target of a correspondence
use(AbstractVariety) -- assign values to variables associated with a variety
variety(AbstractSheaf) -- the variety of an abstract sheaf

Methods that use an abstract variety:

abstractProjectiveSpace(ZZ,AbstractVariety) -- see abstractProjectiveSpace -- make a projective space
abstractProjectiveSpace'(ZZ,AbstractVariety) -- see abstractProjectiveSpace' -- make a projective space
abstractSheaf(AbstractVariety) -- see abstractSheaf(AbstractVariety,RingElement) -- make an abstract sheaf
abstractSheaf(AbstractVariety,QQ) -- see abstractSheaf(AbstractVariety,RingElement) -- make an abstract sheaf
abstractSheaf(AbstractVariety,RingElement) -- make an abstract sheaf
abstractSheaf(AbstractVariety,ZZ) -- see abstractSheaf(AbstractVariety,RingElement) -- make an abstract sheaf
AbstractVariety / AbstractVariety -- get a structure map
abstractVarietyMap(AbstractVariety,AbstractVariety,MethodFunction,MethodFunction) -- see abstractVarietyMap -- make an abstract variety morphism
abstractVarietyMap(AbstractVariety,AbstractVariety,RingMap,MethodFunction) -- see abstractVarietyMap -- make an abstract variety morphism
cotangentBundle(AbstractVariety) -- see cotangentBundle -- get the cotangent bundle
dim(AbstractVariety) -- the dimension of an abstract variety
euler(AbstractVariety)
exceptionalDivisor(AbstractVariety) -- see exceptionalDivisor -- get the exceptional divisor of a blowup
flagBundle(List,AbstractVariety) -- see flagBundle -- make a flag bundle
intersectionRing(AbstractVariety) -- get the intersection ring of an abstract variety
map(FlagBundle,AbstractVariety,AbstractSheaf) -- maps to projective bundles
map(FlagBundle,AbstractVariety,List) -- see map(FlagBundle,AbstractVarietyMap,List) -- make a map from an abstract variety to a flag bundle
OO _ AbstractVariety -- the structure sheaf of an abstract variety
projectiveBundle(ZZ,AbstractVariety) -- see projectiveBundle -- make a projective bundle from an abstract sheaf
projectiveBundle'(ZZ,AbstractVariety) -- see projectiveBundle' -- make a projective bundle from an abstract sheaf
tangentBundle(AbstractVariety) -- see tangentBundle -- get the tangent bundle
tautologicalLineBundle(AbstractVariety) -- see tautologicalLineBundle -- get the tautological line bundle of a flag bundle or abstract variety
todd(AbstractVariety) -- see todd -- compute the Todd class of an abstract sheaf, variety, map

Protected objects of class AbstractVariety:

point -- the default base variety of dimension 0

For the programmer

The object AbstractVariety is a type, with ancestor classes MutableHashTable < HashTable < Thing.