EPY(Arrangement,PolynomialRing) -- compute the Eisenbud-Popescu-Yuzvinsky module of an arrangement

Synopsis

Function: EPY
Usage:

EPY(A) or EPY(A,S) or EPY(I) or EPY(I,S)
Inputs:
- A, a hyperplane arrangement, an arrangement of n hyperplanes, or I, an ideal of the exterior algebra, the quotient by which has a linear, injective resolution
- S, a polynomial ring, an optional polynomial ring in $n$ variables
Outputs:
- a module, the Eisenbud-Popescu-Yuzvinsky module (see below) of I, or if an arrangement is given, of its Orlik-Solomon ideal.

Description

Let $\mathrm{OS}$ denote the Orlik-Solomon algebra of the arrangement ${\mathcal A}$, regarded as a quotient of an exterior algebra $E$. The module $\mathrm{EPY}({\mathcal A})$ is, by definition, the $S$-module which is BGG-dual to the linear, injective resolution of $\mathrm{OS}$ as an $E$-module.

Equivalently, $\mathrm{EPY}({\mathcal A})$ is the single nonzero cohomology module in the Aomoto complex of ${\mathcal A}$. For details, see D. Eisenbud, S. Popescu, S. Yuzvinsky, "Hyperplane arrangement cohomology and monomials in the exterior algebra", Trans. AMS 355 (2003) no 11, 4365-4383, arXiv:math/9912212, as well as Sheaf Algorithms Using the Exterior Algebra, by Wolfram Decker and David Eisenbud, in Computations in algebraic geometry with Macaulay 2, Algorithms and Computations in Mathematics, Springer-Verlag, Berlin, 2001.

i1 : R = QQ[x,y];

i2 : FA = EPY arrangement {x,y,x-y}

o2 = cokernel | -X_1 X_1+X_2+X_3 X_1     |
              | X_2  0           X_1+X_3 |

                                                2
o2 : QQ[X ..X ]-module, quotient of (QQ[X ..X ])
         1   3                           1   3

i3 : betti res FA

            0 1 2
o3 = total: 2 3 1
         0: 2 3 1

o3 : BettiTally

A consequence of the theory is that $\mathrm{EPY}({\mathcal A})$ has a linear, free resolution over the polynomial ring: namely, the Aomoto complex of ${\mathcal A}$. The Betti numbers in the resolution are, up to a suitable shift, equal to the degrees of the graded pieces of $\mathrm{OS}({\mathcal A})$.

i4 : A = arrangement "prism"

o4 = {x , x , x , x , x  + x  + x , x  + x  + x }
       1   2   3   4   1    2    4   1    3    4

o4 : Hyperplane Arrangement

i5 : reduceHilbert hilbertSeries orlikSolomon A

                 2      3     4
     1 + 6T + 15T  + 17T  + 7T
o5 = --------------------------
                  1

o5 : Expression of class Divide

i6 : betti res EPY A

            0  1  2 3 4
o6 = total: 7 17 15 6 1
         0: 7 17 15 6 1

o6 : BettiTally

Ways to use this method: