orlikSolomon(Arrangement,PolynomialRing) -- compute the defining ideal for the Orlik-Solomon algebra

Synopsis

Function: orlikSolomon
Usage:

orlikSolomon(A,E)

orlikSolomon(A,k)

orlikSolomon(A,e)

orlikSolomon(A)
Inputs:
- A, a hyperplane arrangement,
- E, a polynomial ring, a skew-commutative polynomial ring with one variable for each hyperplane with indexed variables, optionally, given by the symbol $e$. The user can also just specify a coefficient ring $k$.
Optional inputs:
- HypAtInfinity => ..., default value 0
- Projective => ..., default value false
- Strategy => ..., default value Matroids
Outputs:
- an ideal, the defining ideal of the Orlik-Solomon algebra of A

Description

The Orlik-Solomon algebra is the cohomology ring of the complement of the hyperplanes, either in complex projective or affine space. The optional Boolean argument Projective specifies which.

A fundamental property is that its Hilbert series is determined by combinatorics: namely, up to a change of variables, it is the characteristic polynomial of the matroid of the arrangement.

i1 : A = typeA(3)

o1 = {x  - x , x  - x , x  - x , x  - x , x  - x , x  - x }
       1    2   1    3   1    4   2    3   2    4   3    4

o1 : Hyperplane Arrangement

i2 : I = orlikSolomon(A,e)

o2 = ideal (e e  - e e  + e e , e e  - e e  + e e , e e  - e e  + e e , e e 
             4 5    4 6    5 6   2 3    2 6    3 6   1 3    1 5    3 5   1 2
     ------------------------------------------------------------------------
     - e e  + e e )
        1 4    2 4

o2 : Ideal of QQ[e ..e ]
                  1   6

i3 : reduceHilbert hilbertSeries I

                 2     3
     1 + 6T + 11T  + 6T
o3 = -------------------
              1

o3 : Expression of class Divide

i4 : characteristicPolynomial matroid A

      3     2
o4 = x  - 6x  + 11x - 6

o4 : ZZ[x]

The cohomology ring of the complement of an arrangement in projective space is most naturally described as the subalgebra of the Orlik-Solomon algebra generated in degree $1$ by elements whose coefficients sum to $0$.

This is inconvenient for Macaulay2; on the other hand, one can choose a chart for projective space that places a hyperplane of the arrangement at infinity. This expresses the projective Orlik-Solomon algebra as a quotient of a polynomial ring.

By selecting the Projective option, the user can specify which hyperplane is placed at infinity. By default, the first one in order is used.

i5 : I' = orlikSolomon(A,Projective=>true,HypAtInfinity=>2)

o5 = ideal (e e  - e e  + e e , e e  - e e  + e e , e e  - e e  + e e , e e 
             4 5    4 6    5 6   2 3    2 6    3 6   1 3    1 5    3 5   1 2
     ------------------------------------------------------------------------
     - e e  + e e , e )
        1 4    2 4   3

o5 : Ideal of QQ[e ..e ]
                  1   6

i6 : reduceHilbert hilbertSeries I'

                2
     1 + 5T + 6T
o6 = ------------
           1

o6 : Expression of class Divide

The method caches the list of circuits of the arrangement. By default, the method uses the Matroids package to compute the Orlik-Solomon ideal. The option "Strategy=>Popescu" uses code by Sorin Popescu instead.

Caveat

The coefficient rings of the Orlik-Solomon algebra and of the arrangement, respectively, are unrelated.

Ways to use this method: