orlikTerao(CentralArrangement,PolynomialRing) -- compute the defining ideal for the Orlik-Terao algebra

Synopsis

Function: orlikTerao
Usage:

orlikTerao(A,S)

orlikTerao(A,x)

orlikTerao(A)
Inputs:
- A, a central hyperplane arrangement, a hyperplane arrangement
- S, a polynomial ring, a polynomial ring with one variable for each hyperplane with indexed variables, optionally, given by the symbol $x$.
Optional inputs:
- NaiveAlgorithm => a Boolean value, default value false
Outputs:
- an ideal, the defining ideal of the Orlik-Terao algebra of A

Description

The Orlik-Terao algebra of an arrangement is the subalgebra of rational functions $k[1/f_1,1/f_2,\ldots,1/f_n]$, where the $f_i$'s are the defining forms for the hyperplanes. The method produces an ideal presenting the Orlik-Terao algebra as a quotient of a polynomial ring in $n$ variables.

i1 : R = QQ[x,y,z];

i2 : orlikTerao arrangement {x,y,z,x+y+z}

o2 = ideal(y y y  - y y y  - y y y  - y y y )
            1 2 3    1 2 4    1 3 4    2 3 4

o2 : Ideal of QQ[y ..y ]
                  1   4

The defining ideal above has one generator given by the single relation coming from the identity $x+y+z-(x+y+z)=0$. In general, the ideal is homogeneous with respect to the standard grading, but its degrees of generation are not straightforward. The projective variety cut out by this ideal is also called the reciprocal plane.

i3 : I = orlikTerao arrangement "braid"

o3 = ideal (y y  - y y  + y y , y y  + y y  - y y , y y  + y y  - y y , y y 
             4 5    4 6    5 6   2 3    2 6    3 6   1 3    1 5    3 5   1 2
     ------------------------------------------------------------------------
     + y y  - y y )
        1 4    2 4

o3 : Ideal of QQ[y ..y ]
                  1   6

i4 : betti res I

            0 1 2 3
o4 = total: 1 4 5 2
         0: 1 . . .
         1: . 4 2 .
         2: . . 3 2

o4 : BettiTally

i5 : OT := comodule I;

i6 : apply(1+dim OT, i-> 0 == Ext^i(OT, ring OT))

o6 = {true, true, true, false}

o6 : List

As the example above hints, the Orlik-Terao algebra is always Cohen-Macaulay: see N. J. Proudfoot and D. E. Speyer, A broken circuit ring, Beitrage zur Algebra und Geometrie, 2006, arXiv:math/0410069.

Unlike the Orlik-Solomon algebra, the isomorphism type of the Orlik-Terao algebra is not a matroid invariant: see the example here. However, Terao proved that the Hilbert series of the Orlik-Terao algebra is a matroid invariant: it is given by the Poincaré polynomial: \[ \sum_{i\geq 0}\dim (S/I)_it^i=\pi({\mathcal A},t/(1-t)). \]

i7 : p = poincare arrangement "braid"

                 2     3
o7 = 1 + 6T + 11T  + 6T

o7 : ZZ[T]

i8 : F = frac QQ[T]; f = map(F,ring p);

o9 : RingMap F <-- ZZ[T]

i10 : sub(f p, {T=>T/(1-T)})

            2
        - 2T  - 3T - 1
o10 = -----------------
       3     2
      T  - 3T  + 3T - 1

o10 : frac F

i11 : reduceHilbert hilbertSeries I

                 2
      1 + 3T + 2T
o11 = ------------
               3
        (1 - T)

o11 : Expression of class Divide

Ways to use this method: