arrangement(List,Ring) -- make a hyperplane arrangement

Synopsis

Function: arrangement
Usage:

arrangement(L, R)

arrangement L
Inputs:
- L, a list, of affine-linear equations in the ring $R$ or a ring element that is a product of linear forms
- R, a ring, a polynomial ring or linear quotient of a polynomial ring
Outputs:
- a hyperplane arrangement, determined by the input data

Description

A hyperplane is an affine-linear subspace of codimension one. An arrangement is a finite set of hyperplanes. When each hyperplane contains the origin, the arrangement is central.

Probably the best-known hyperplane arrangement is the braid arrangement consisting of all the diagonal hyperplanes. In $4$-space, it is constructed as follows.

i1 : S = QQ[w,x,y,z];

i2 : A3 = arrangement {w-x, w-y, w-z, x-y, x-z, y-z}

o2 = {w - x, w - y, w - z, x - y, x - z, y - z}

o2 : Hyperplane Arrangement

i3 : assert isCentral A3

When a hyperplane arrangement is created from a product of linear forms, the order of the factors is not preserved.

i4 : A3' = arrangement ((w-x)*(w-y)*(w-z)*(x-y)*(x-z)*(y-z))

o4 = {y - z, x - z, x - y, w - z, w - y, w - x}

o4 : Hyperplane Arrangement

i5 : assert(A3 != A3')

i6 : arrangement (x^2*y^2*(x^2-y^2)*(x^2-z^2))

o6 = {y, y, x, x, x - z, x + z, x - y, x + y}

o6 : Hyperplane Arrangement

The package can recognize that a polynomial splits into linear forms over the base field.

i7 : kk = toField(QQ[p]/(p^2+p+1)) -- toField is necessary so that M2 treats this as a field

o7 = kk

o7 : PolynomialRing

i8 : R = kk[s,t]

o8 = R

o8 : PolynomialRing

i9 : arrangement (s^3-t^3)

o9 = {s - t, s - p*t, s + (p + 1)t}

o9 : Hyperplane Arrangement

If we project onto a linear subspace, then we obtain an essential arrangement, meaning that the rank of the arrangement is equal to the dimension of its ambient vector space.

i10 : R = S/ideal(w+x+y+z);

i11 : A3'' = arrangement({w-x,w-y,w-z,x-y,x-z,y-z}, R)

o11 = {- 2x - y - z, - x - 2y - z, - x - y - 2z, x - y, x - z, y - z}

o11 : Hyperplane Arrangement

i12 : ring A3''

o12 = R

o12 : QuotientRing

i13 : assert(rank A3'' === dim ring A3'')

The trivial arrangement has no equations.

i14 : trivial = arrangement({},S)

o14 = {}

o14 : Hyperplane Arrangement

i15 : ring trivial

o15 = S

o15 : PolynomialRing

i16 : assert isCentral trivial

Caveat

If the entries in $L$ are not ring elements in $R$, then the induced identity map is used to map them from the ring of first element in $L$ into $R$.

Ways to use this method: