arrangement(Matrix,Ring) -- make a hyperplane arrangement

Synopsis

Function: arrangement
Usage:

arrangement(M, R)

arrangement M
Inputs:
- M, a matrix, a matrix whose columns represent linear forms defining hyperplanes
- R, a ring, a polynomial ring or linear quotient of a polynomial ring
Outputs:
- a hyperplane arrangement, determined by the input data

Description

A hyperplane is an affine-linear subspace of codimension one. An arrangement is a finite set of hyperplanes. When each hyperplane contains the origin, the arrangement is central.

Probably the best-known hyperplane arrangement is the braid arrangement consisting of all the diagonal hyperplanes. In $4$-space, it is constructed as follows.

i1 : S = QQ[w,x,y,z];

i2 : A3 = arrangement(matrix{{1,1,1,0,0,0},{-1,0,0,1,1,0},{0,-1,0,-1,0,1},{0,0,-1,0,-1,-1}}, S)

o2 = {w - x, w - y, w - z, x - y, x - z, y - z}

o2 : Hyperplane Arrangement

i3 : assert isCentral A3

If we project along onto a subspace, then we obtain an essential arrangement, meaning that the rank of the arrangement is equal to the dimension of its ambient vector space.

i4 : R = S/ideal(w+x+y+z);

i5 : A3' = arrangement(matrix{{1,1,1,0,0,0},{-1,0,0,1,1,0},{0,-1,0,-1,0,1},{0,0,-1,0,-1,-1}}, R)

o5 = {- 2x - y - z, - x - 2y - z, - x - y - 2z, x - y, x - z, y - z}

o5 : Hyperplane Arrangement

i6 : ring A3'

o6 = R

o6 : QuotientRing

i7 : assert(rank A3' === dim ring A3')

The trivial arrangement has no equations.

i8 : trivial = arrangement(map(S^4,S^0,0),S)

o8 = {}

o8 : Hyperplane Arrangement

i9 : ring trivial

o9 = S

o9 : PolynomialRing

i10 : assert isCentral trivial

Ways to use this method: